Light Show

Note

🌟 Welcome to the SunFounder Facebook Community! Whether you’re into Raspberry Pi, Arduino, or ESP32, you’ll find inspiration, help ideas here.

• ✅ Be the first to get free learning resources.

• ✅ Stay updated on new products & exclusive giveaways.

• ✅ Share your creations and get real feedback.

• 👉 Need faster updates or support? Click [here] join our Facebook community

• 👉 Or join our WhatsApp group: Click [here]

Kit purchase

Looking for parts? Check out our all-in-one kits below — packed with components, beginner-friendly guides, and tons of fun.

Name	Includes Arduino board	PURCHASE LINK
Ultimate Sensor Kit	Arduino Uno R4 Minima	BUY
Elite Explorer Kit	Arduino Uno R4 WiFi	BUY
3 in 1 Ultimate Starter Kit	Arduino Uno R4 Minima	BUY
Universal Maker Sensor Kit	×	BUY

Course Introduction

In this lesson, you will learn how to use Arduino along with LEDs, and resistors to create a light show.

Note

If this is your first time working with an Arduino project, we recommend downloading and reviewing the basic materials first.

• 1.1 Install Arduino IDE(Important)

• 1.2 Introduce of Arduino IDE

Required Components

In this project, we need the following components:

SN	COMPONENT INTRODUCTION	QUANTITY	PURCHASE LINK
1	Arduino UNO R4 Minima	1	BUY
2	USB Type-C cable	1
3	Breadboard	1	BUY
4	Wires	Several	BUY
5	1kΩ resistor	Several	BUY
6	LED	Several	BUY

Wiring

Common Connections:

• LED

  • Connect the LEDs cathode to negative power bus on the breadboard, and the LEDs anode to a 1kΩ resistor then to the 2 to 13 on the Arduino.

Writing the Code

Note

• You can copy this code into Arduino IDE.

• Don’t forget to select the board(Arduino UNO R4 Minima) and the correct port before clicking the Upload button.

// Define LED pins
const int ledPins[] = {2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13};
const int numLeds = 12;

void setup() {
  // Set all LED pins as outputs and turn them off
  for (int i = 0; i < numLeds; i++) {
    pinMode(ledPins[i], OUTPUT);
    digitalWrite(ledPins[i], LOW);
  }
}

void loop() {
  waterfallEffect(true);    // Waterfall (forward)
  waterfallEffect(false);   // Waterfall (reverse)
  bouncingEffect();         // Bouncing (in and out)
  bouncingEffect();
  waveEffect();             // Wave pattern
  waveEffect();
  alternatingEffect();      // Alternating even/odd LEDs
  runningBackEffect();      // Running light back and forth
  ladderEffect();           // Ladder on/off sequence
  progressiveKeepEffect();  // Progressive lighting
  progressiveKeepEffect();
  dualSlidingEffect();      // Dual sliding from ends to center and back
  dualSlidingEffect();
  dualSlidingEffect();
}

void dualSlidingEffect() {
  // Move inward, blinking symmetrically
  for (int i = 0; i < numLeds / 2; i++) {
    for (int j = 0; j < 3; j++) {
      digitalWrite(ledPins[i], HIGH);
      digitalWrite(ledPins[numLeds - 1 - i], HIGH);
      delay(10);
      digitalWrite(ledPins[i], LOW);
      digitalWrite(ledPins[numLeds - 1 - i], LOW);
      delay(10);
    }
    delay(50);
  }

  // Move outward, blinking symmetrically
  for (int i = numLeds / 2 - 1; i >= 0; i--) {
    for (int j = 0; j < 3; j++) {
      digitalWrite(ledPins[i], HIGH);
      digitalWrite(ledPins[numLeds - 1 - i], HIGH);
      delay(10);
      digitalWrite(ledPins[i], LOW);
      digitalWrite(ledPins[numLeds - 1 - i], LOW);
      delay(10);
    }
    delay(50);
  }
}

// Waterfall effect: LEDs turn on/off in sequence
void waterfallEffect(bool direction) {
  if (direction) {
    for (int i = 0; i < numLeds; i++) {
      digitalWrite(ledPins[i], HIGH);
      delay(50);
    }
    for (int i = 0; i < numLeds; i++) {
      digitalWrite(ledPins[i], LOW);
      delay(50);
    }
  } else {
    for (int i = numLeds - 1; i >= 0; i--) {
      digitalWrite(ledPins[i], HIGH);
      delay(50);
    }
    for (int i = numLeds - 1; i >= 0; i--) {
      digitalWrite(ledPins[i], LOW);
      delay(50);
    }
  }
}

// Bouncing effect: inward and outward lighting
void bouncingEffect() {
  for (int i = 0; i < numLeds / 2; i++) {
    digitalWrite(ledPins[i], HIGH);
    digitalWrite(ledPins[numLeds - 1 - i], HIGH);
    delay(50);
  }
  for (int i = 0; i < numLeds / 2; i++) {
    digitalWrite(ledPins[i], LOW);
    digitalWrite(ledPins[numLeds - 1 - i], LOW);
    delay(50);
  }

  for (int i = numLeds / 2 - 1; i >= 0; i--) {
    digitalWrite(ledPins[i], HIGH);
    digitalWrite(ledPins[numLeds - 1 - i], HIGH);
    delay(50);
  }
  for (int i = numLeds / 2 - 1; i >= 0; i--) {
    digitalWrite(ledPins[i], LOW);
    digitalWrite(ledPins[numLeds - 1 - i], LOW);
    delay(50);
  }
}

// Wave effect: LEDs create a moving wave
void waveEffect() {
  for (int i = 0; i < numLeds; i++) {
    digitalWrite(ledPins[i], HIGH);
    if (i > 1) digitalWrite(ledPins[i - 2], LOW);
    delay(50);
  }
  for (int i = numLeds - 1; i >= 0; i--) {
    digitalWrite(ledPins[i], HIGH);
    if (i < numLeds - 2) digitalWrite(ledPins[i + 2], LOW);
    delay(50);
  }
  for (int i = 0; i < 2; i++) {
    digitalWrite(ledPins[numLeds - 1 - i], LOW);
  }
}

// Alternating blink effect: even/odd LEDs alternate
void alternatingEffect() {
  for (int i = 0; i < 5; i++) {
    for (int j = 0; j < numLeds; j += 2) {
      digitalWrite(ledPins[j], HIGH);
      digitalWrite(ledPins[j + 1], LOW);
    }
    delay(300);
    for (int j = 0; j < numLeds; j += 2) {
      digitalWrite(ledPins[j], LOW);
      digitalWrite(ledPins[j + 1], HIGH);
    }
    delay(300);
  }
}

// Running effect: light moves left-to-right and back
void runningBackEffect() {
  for (int i = 0; i < numLeds; i++) {
    digitalWrite(ledPins[i], HIGH);
    delay(50);
    digitalWrite(ledPins[i], LOW);
  }
  for (int i = numLeds - 1; i >= 0; i--) {
    digitalWrite(ledPins[i], HIGH);
    delay(50);
    digitalWrite(ledPins[i], LOW);
  }
}

// Ladder effect: sequential on/off like climbing steps
void ladderEffect() {
  for (int i = 0; i < numLeds; i++) {
    digitalWrite(ledPins[i], HIGH);
    delay(50);
  }
  for (int i = numLeds - 1; i >= 0; i--) {
    digitalWrite(ledPins[i], LOW);
    delay(50);
  }
}

// Progressive keep effect: gradually light LEDs and keep previous ones on
void progressiveKeepEffect() {
  for (int round = 0; round < numLeds; round++) {
    for (int i = 0; i < numLeds; i++) {
      digitalWrite(ledPins[i], LOW);
    }

    for (int i = numLeds - 1; i >= numLeds - round; i--) {
      digitalWrite(ledPins[i], HIGH);
    }

    for (int i = 0; i < numLeds - round; i++) {
      digitalWrite(ledPins[i], HIGH);
      if (i > 0) {
        digitalWrite(ledPins[i - 1], LOW);
      }
      delay(50);
    }

    if (numLeds - round - 1 >= 0) {
      digitalWrite(ledPins[numLeds - round - 1], LOW);
    }
  }
}

// Center spread effect: LEDs light from the center outwards and then back
// (Not called in the loop)
void centerSpreadEffect() {
  int center = numLeds / 2;
  for (int offset = 0; offset < center; offset++) {
    digitalWrite(ledPins[center - offset - 1], HIGH);
    digitalWrite(ledPins[center + offset], HIGH);
    delay(100);
  }
  for (int offset = center - 1; offset >= 0; offset--) {
    digitalWrite(ledPins[center - offset - 1], LOW);
    digitalWrite(ledPins[center + offset], LOW);
    delay(100);
  }
}