注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。
学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。
独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。
特別割引：最新製品の独占割引をお楽しみください。
祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

QMC5883L

概要

このチュートリアルでは、GY-87 IMUモジュールに焦点を当て、特にそのQMC5883L磁力計について探求します。チュートリアルの最初の部分では、QMC5883L磁力計の校正方法について案内します。これは正確な磁場測定に不可欠です。Arduinoに校正スケッチをアップロードし、リアルタイムで校正を行い、プロジェクトにこれらの設定を適用する方法を学びます。チュートリアルの第二部では、Arduino Uno上でMPU6050（加速度計とジャイロスコープ）とQMC5883LをAdafruit MPU6050およびQMC5883LCompassライブラリを使って初期化する方法を取り上げます。センサーデータを読み取り、シリアルモニターに表示する基本的なスキルを身につけます。これは、ナビゲーション、動作追跡、方向検出などのアプリケーションに不可欠です。

必要なコンポーネント

このプロジェクトでは、以下のコンポーネントが必要です。

キット全体を購入するのは便利です。リンクはこちら：

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

下記のリンクから個別に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ジャンパーワイヤー	購入
GY-87 IMUモジュール	-

配線図

回路図

ライブラリのインストール

注釈

ライブラリをインストールするには、Arduino Library Managerを使用します。

「Adafruit MPU6050」 を検索してインストール

各ライブラリをインストールする際は、すべての依存関係のインストールを選択してください。

「QMC5883LCompass」 を検索してインストール

QMC5883Lの校正

注釈

09-gy87_compass_calibration.ino ファイルを elite-explorer-kit-main\basic_project\09-gy87_compass_calibration のパスから直接開くことができます。
または、このコードをArduino IDEにコピーします。

09-gy87_compass_calibration.ino

/*
  This code is used to calibrate the QMC5883L magnetometer in the gy-87 module.

  Upload this calibration sketch onto your Arduino to provide calibration for 
  your QMC5883L chip. After upload, run the serial monitor and follow the directions.
  When prompted, copy the last line into your project's actual sketch.

  Board: Arduino Uno R4
  Component: GY-87 IMU Module
  Library: https://github.com/adafruit/Adafruit_MPU6050  (Adafruit MPU6050 by Adafruit)
           https://github.com/mprograms/QMC5883LCompass  (QMC5883LCompass by MPrograms)
           https://github.com/adafruit/Adafruit-BMP085-Library  (Adafruit BMP085 Library by Adafruit)
*/

#include <Adafruit_MPU6050.h>
#include <QMC5883LCompass.h>

Adafruit_MPU6050 mpu;
QMC5883LCompass compass;

void setup() {
  Serial.begin(9600);
  
  initializeMPU6050();

  // Enable I2C bypass on MPU6050 to directly access the QMC5883L magnetometer
  mpu.setI2CBypass(true);

  compass.init();
  
  Serial.println("This will provide calibration settings for your QMC5883L chip. When prompted, move the magnetometer in all directions until the calibration is complete.");
  Serial.println("Calibration will begin in 5 seconds.");
  delay(5000);

  Serial.println("CALIBRATING. Keep moving your sensor...");
  compass.calibrate();

  Serial.println("DONE. Copy the lines below and paste it into your projects sketch.);");
  Serial.println();
  Serial.print("compass.setCalibrationOffsets(");
  Serial.print(compass.getCalibrationOffset(0));
  Serial.print(", ");
  Serial.print(compass.getCalibrationOffset(1));
  Serial.print(", ");
  Serial.print(compass.getCalibrationOffset(2));
  Serial.println(");");
  Serial.print("compass.setCalibrationScales(");
  Serial.print(compass.getCalibrationScale(0));
  Serial.print(", ");
  Serial.print(compass.getCalibrationScale(1));
  Serial.print(", ");
  Serial.print(compass.getCalibrationScale(2));
  Serial.println(");");
}

void loop() {
  delay(1000);
}

void initializeMPU6050() {
  // Check if the MPU6050 sensor is detected
  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1)
      ;  // Halt if sensor not found
  }
  Serial.println("MPU6050 Found!");

  // set accelerometer range to +-8G
  mpu.setAccelerometerRange(MPU6050_RANGE_8_G);

  // set gyro range to +- 500 deg/s
  mpu.setGyroRange(MPU6050_RANGE_500_DEG);

  // set filter bandwidth to 21 Hz
  mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);

  Serial.println("");
  delay(100);
}

コードのアップロード後、シリアルモニターを開きます。シリアルモニターの指示に従ってQMC5883Lを校正します。センサーの移動を求められた場合、図8の校正方法を使用することをお勧めします。または、センサーを地面と平行に保ち、シリアルモニターが校正が完了したことを示すまで時計回りまたは反時計回りに回転させます。

校正データがすべて収集されると、スケッチは compass.setCalibrationOffsets(-375.00, -179.00, 85.00); や compass.setCalibrationScales(1.04, 0.96, 1.01); のようなコードを提供します。このコードをコピーしてください。今後の参考のために保存しておくことをお勧めします。

QMC5883Lを使用する場合：プロジェクトのスケッチを開き、 compass.init() の呼び出しの直下にコピーしたコードを貼り付けます。以下のようにします：

void initializeQMC5883L() {

  compass.init();

  // You should replace the code below according to your calibration results
  compass.setCalibrationOffsets(-375.00, -179.00, 85.00);
  compass.setCalibrationScales(1.04, 0.96, 1.01);

}

コード

注釈

磁力計はコンパスとして使用する前に校正する必要があり(QMC5883Lの校正)、使用中に水平に保持し、 鉄製品、磁化した材料、電流を運ぶワイヤーから遠ざける 必要があります。

注釈

09-gy87_qmc5883l.ino ファイルを elite-explorer-kit-main\basic_project\09-gy87_qmc5883l のパスから直接開くことができます。
または、このコードをArduino IDEにコピーします。
校正手順から得られたコードを、関数 initializeQMC5883L() の compass.init() のコードの下に配置します。

09-gy87_qmc5883l.ino

/*
  This Arduino code interfaces with the GY-87 IMU  module, focusing specifically on 
  the QMC5883L magnetometer for measuring magnetic field data. It initializes the 
  QMC5883L sensor and continuously outputs its readings, including directional data, 
  to the Serial Monitor.
  
  Board: Arduino Uno R4
  Component: GY-87 IMU Module
  Library: https://github.com/adafruit/Adafruit_MPU6050  (Adafruit MPU6050 by Adafruit)
           https://github.com/mprograms/QMC5883LCompass  (QMC5883LCompass by MPrograms)
*/

// Include required libraries
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
#include <QMC5883LCompass.h>

// Initialize sensor objects
Adafruit_MPU6050 mpu;
QMC5883LCompass compass;

void setup() {
  // Initialize the serial communication with a baud rate of 9600
  Serial.begin(9600);

  // Initialize the MPU6050 sensor (accelerometer and gyroscope)
  initializeMPU6050();

  // Enable I2C bypass on MPU6050 to directly access the QMC5883L magnetometer
  mpu.setI2CBypass(true);

  // Initialize the QMC5883L magnetometer sensor
  initializeQMC5883L();
}


void loop() {
  // Print QMC5883L data
  printQMC5883L();

  delay(500);
}

void initializeQMC5883L() {
  compass.init();

  // You should replace the code below according to your calibration results
  compass.setCalibrationOffsets(-549.00, -66.00, 160.00);
  compass.setCalibrationScales(0.97, 1.02, 1.02);
}

void printQMC5883L() {

  Serial.println();
  Serial.println("QMC5883L ------------");

  int x, y, z, a;
  char myArray[3];

  compass.read();

  x = compass.getX();
  y = compass.getY();
  z = compass.getZ();

  a = compass.getAzimuth();

  compass.getDirection(myArray, a);

  Serial.print("X: ");
  Serial.print(x);

  Serial.print(" Y: ");
  Serial.print(y);

  Serial.print(" Z: ");
  Serial.print(z);

  Serial.print(" Azimuth: ");
  Serial.print(a);

  Serial.print(" Direction: ");
  Serial.print(myArray[0]);
  Serial.print(myArray[1]);
  Serial.println(myArray[2]);

  Serial.println("QMC5883L ------------");
  Serial.println();
}

void initializeMPU6050() {
  // Check if the MPU6050 sensor is detected
  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1)
      ;  // Halt if sensor not found
  }
  Serial.println("MPU6050 Found!");

  // set accelerometer range to +-8G
  mpu.setAccelerometerRange(MPU6050_RANGE_8_G);

  // set gyro range to +- 500 deg/s
  mpu.setGyroRange(MPU6050_RANGE_500_DEG);

  // set filter bandwidth to 21 Hz
  mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);

  Serial.println("");
  delay(100);
}

コード解析

ライブラリのインクルードとセンサーの初期化このセクションでは、MPU6050およびQMC5883Lセンサーに必要なライブラリをインクルードし、そのオブジェクトを初期化します。
```
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
#include <QMC5883LCompass.h>

Adafruit_MPU6050 mpu;
QMC5883LCompass compass;
```

Setup関数

シリアル通信、MPU6050センサーを初期化し、MPU6050をI2Cバイパスモードに設定してQMC5883L磁力計への直接アクセスを可能にします。その後、QMC5883L磁力計を初期化します。

void setup() {
  // Initialize the serial communication with a baud rate of 9600
  Serial.begin(9600);

  // Initialize the MPU6050 sensor (accelerometer and gyroscope)
  initializeMPU6050();

  // Enable I2C bypass on MPU6050 to directly access the QMC5883L magnetometer
  mpu.setI2CBypass(true);

  // Initialize the QMC5883L magnetometer sensor
  initializeQMC5883L();
}

ループ関数

QMC5883L磁力計からデータを連続的に読み取り、シリアルモニターに出力します。
```
void loop() {
  printQMC5883L();
  delay(500);
}
```

QMC5883L初期化関数

QMC5883L磁力計を初期化し、校正します。校正値は特定の校正データに基づいて調整する必要があります。(QMC5883Lの校正)

void initializeQMC5883L() {
  compass.init();

  // You should replace the code below according to your calibration results
  compass.setCalibrationOffsets(-549.00, -66.00, 160.00);
  compass.setCalibrationScales(0.97, 1.02, 1.02);
}

QMC5883Lデータ表示関数

この関数は磁力計のX、Y、Z値と方位角を読み取り、シリアルモニターに出力します。

void printQMC5883L() {

  Serial.println();
  Serial.println("QMC5883L ------------");

    int x, y, z, a;
    char myArray[3];

    compass.read();

    x = compass.getX();
    y = compass.getY();
    z = compass.getZ();

    a = compass.getAzimuth();

    compass.getDirection(myArray, a);

    Serial.print("X: ");
    Serial.print(x);

    Serial.print(" Y: ");
    Serial.print(y);

    Serial.print(" Z: ");
    Serial.print(z);

    Serial.print(" Azimuth: ");
    Serial.print(a);

    Serial.print(" Direction: ");
    Serial.print(myArray[0]);
    Serial.print(myArray[1]);
    Serial.println(myArray[2]);

  Serial.println("QMC5883L ------------");
  Serial.println();
}