注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

• エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。

• 学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。

• 独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。

• 特別割引：最新製品の独占割引をお楽しみください。

• 祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

GY-87 IMUモジュール

GY-87モジュールは、MPU6050、QMC5883L、BMP180の3つのセンサーチップが装備されており、それぞれ独自の機能を提供します。MPU6050はジャイロスコープと加速度計を組み合わせて運動追跡を行い、QMC5883Lは方向感知用の磁力計として機能し、BMP180は気圧と温度を測定するために使用されます。これらはI2Cプロトコルを使用してArduinoと効果的に通信することができます。

これらのセンサーは、I2Cプロトコルを介してシームレスに統合されており、Arduinoのようなプラットフォームとの効率的な通信を確保しています。GY-87モジュールの各センサーは、固有のI2Cアドレスを通じてアクセスできます：MPU6050は0x68、QMC5883Lは0x0D、BMP180は0x77でアクセスします。

各センサーチップの個別チュートリアル：

• BMP180
• MPU6050
• QMC5883L

これらの3つのチップを同時に使用したい場合は、以下の簡単な例があります：

注釈

• ファイル 09-gy87.ino を直接 elite-explorer-kit-main\basic_project\09-gy87 のパスから開くことができます。

• または、このコードをArduino IDEにコピーしてください。

注釈

ライブラリをインストールするには、Arduinoライブラリマネージャーを使用してください。

• 「Adafruit MPU6050」 を検索してインストール

  各ライブラリをインストールする際は、すべての依存関係のインストールも選択してください。

  

• 「Adafruit Unified Sensor」 を検索してインストール

• 「QMC5883LCompass」 を検索してインストール

• 「Adafruit BMP085 Library」 を検索してインストール

09-gy87.ino

/*
  This Arduino code is designed to work with the GY-87 IMU (Inertial Measurement Unit) module, 
  which is a multi-sensor module containing three individual sensors: MPU6050 (Accelerometer and Gyroscope), 
  QMC5883L Magnetometer, and BMP180 (Barometric Pressure and Temperature). The code initializes these 
  sensors and continuously prints their readings to the Serial Monitor.
  
  Board: Arduino Uno R4
  Component: GY-87 IMU Module
  Library: https://github.com/adafruit/Adafruit_MPU6050  (Adafruit MPU6050 by Adafruit)
           https://github.com/mprograms/QMC5883LCompass  (QMC5883LCompass by MPrograms)
           https://github.com/adafruit/Adafruit-BMP085-Library  (Adafruit BMP085 Library by Adafruit)
*/

// Include required libraries
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
#include <Adafruit_BMP085.h>
#include <QMC5883LCompass.h>

// Initialize sensor objects
Adafruit_MPU6050 mpu;
Adafruit_BMP085 bmp;
QMC5883LCompass compass;

void setup() {
  // Initialize the serial communication with a baud rate of 9600
  Serial.begin(9600);

  // Initialize the MPU6050 sensor (accelerometer and gyroscope)
  initializeMPU6050();

  // Enable I2C bypass on MPU6050 to directly access the QMC5883L magnetometer
  mpu.setI2CBypass(true);

  // Initialize the QMC5883L magnetometer sensor
  initializeQMC5883L();

  // Initialize BMP180 barometric sensor
  initializeBMP180();
}


void loop() {
  // Print MPU6050 data
  printMPU6050();

  // Print QMC5883L data
  printQMC5883L();

  // Print BMP180 data
  printBMP180();
  
  delay(500);
}

void initializeQMC5883L() {

  compass.init();

  // You should replace the code below according to your calibration results
  compass.setCalibrationOffsets(-458.00, -310.00, -362.00);
  compass.setCalibrationScales(0.79, 0.79, 2.19);

}

void printQMC5883L() {

  Serial.println();
  Serial.println("QMC5883L ------------");

	int x, y, z, a;
	char myArray[3];
	
	compass.read();
  
	x = compass.getX();
	y = compass.getY();
	z = compass.getZ();
	
	a = compass.getAzimuth();

	compass.getDirection(myArray, a);
  
	Serial.print("X: ");
	Serial.print(x);

	Serial.print(" Y: ");
	Serial.print(y);

	Serial.print(" Z: ");
	Serial.print(z);

	Serial.print(" Azimuth: ");
	Serial.print(a);

	Serial.print(" Direction: ");
	Serial.print(myArray[0]);
	Serial.print(myArray[1]);
	Serial.println(myArray[2]);

  Serial.println("QMC5883L ------------");
  Serial.println();
}


void initializeMPU6050() {
  // Check if the MPU6050 sensor is detected
  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1)
      ;  // Halt if sensor not found
  }
  Serial.println("MPU6050 Found!");

  // set accelerometer range to +-8G
  mpu.setAccelerometerRange(MPU6050_RANGE_8_G);

  // set gyro range to +- 500 deg/s
  mpu.setGyroRange(MPU6050_RANGE_500_DEG);

  // set filter bandwidth to 21 Hz
  mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);

  Serial.println("");
  delay(100);
}

void printMPU6050() {

  Serial.println();
  Serial.println("MPU6050 ------------");

  /* Get new sensor events with the readings */
  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);

  /* Print out the values */
  Serial.print("Acceleration X: ");
  Serial.print(a.acceleration.x);
  Serial.print(", Y: ");
  Serial.print(a.acceleration.y);
  Serial.print(", Z: ");
  Serial.print(a.acceleration.z);
  Serial.println(" m/s^2");

  Serial.print("Rotation X: ");
  Serial.print(g.gyro.x);
  Serial.print(", Y: ");
  Serial.print(g.gyro.y);
  Serial.print(", Z: ");
  Serial.print(g.gyro.z);
  Serial.println(" rad/s");

  Serial.print("Temperature: ");
  Serial.print(temp.temperature);
  Serial.println(" degC");

  Serial.println("MPU6050 ------------");
  Serial.println();
}

void initializeBMP180() {
  // Start BMP180 initialization
  if (!bmp.begin()) {
    Serial.println("Could not find a valid BMP180 sensor, check wiring!");
    while (1)
      ;  // Halt if sensor not found
  }
  Serial.println("BMP180 Found!");
}

void printBMP180() {
  Serial.println();
  Serial.println("BMP180 ------------");
  Serial.print("Temperature = ");
  Serial.print(bmp.readTemperature());
  Serial.println(" *C");

  Serial.print("Pressure = ");
  Serial.print(bmp.readPressure());
  Serial.println(" Pa");

  // Calculate altitude assuming 'standard' barometric
  // pressure of 1013.25 millibar = 101325 Pascal
  Serial.print("Altitude = ");
  Serial.print(bmp.readAltitude());
  Serial.println(" meters");

  Serial.print("Pressure at sealevel (calculated) = ");
  Serial.print(bmp.readSealevelPressure());
  Serial.println(" Pa");
  Serial.println("BMP180 ------------");
  Serial.println();
}

注釈

磁力計は使用前にキャリブレーション(QMC5883Lの校正)が必要であり、使用時に水平に保持し、 鉄製品、磁化された材料、電流を運ぶワイヤーから離しておく 必要があります。

コードがArduino Uno R4に正常にアップロードされると、シリアルモニターが活動し始め、GY-87 IMUモジュールからのセンサーデータが連続して表示されます。このモジュールには、加速度計とジャイロスコープの読み取りを行うMPU6050、磁力計の読み取りを行うQMC5883L、気圧と温度の読み取りを行うBMP180の3つの個別のセンサーが組み込まれています。