注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。
学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。
独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。
特別割引：最新製品の独占割引をお楽しみください。
祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

スマートファン

このArduinoプロジェクトでは、ファンの速度が自動的に調整され、温度を適切な範囲内に保ちます。また、ユーザーはボタンを通じて手動モードに入り、ファンを最大速度で操作できます。

必要なコンポーネント

このプロジェクトには以下のコンポーネントが必要です。

全体のキットを購入すると便利です。こちらがリンクです：

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

以下のリンクから別々に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ブレッドボード	購入
ジャンパーワイヤー	購入
抵抗器	購入
LED	購入
ボタン	購入
サーミスター	購入
DCモーター	購入
TA6586 - モータードライバーIC	-
電源モジュール	-

配線図

回路図

コード

注釈

ファイル 06_smart_fan.ino を elite-explorer-kit-main\fun_project\06_smart_fan のパスから直接開くことができます。
または、このコードをArduino IDEにコピーしてください。

06_smart_fan.ino

/*
  This code controls a DC motor fan based on temperature readings from a thermistor. 
  It includes a manual override feature using a button. In automatic mode, the fan speed 
  is controlled according to the temperature. In manual mode, the fan runs at full speed. 
  LEDs are used to indicate the current mode (auto or manual).

  Board: Arduino Uno R4 
  Component: LED, button, thermistor, and DC motor.
*/

// Pin assignments
#define MOTOR_PIN 9         // PWM compatible pin for DC motor
#define TEMP_SENSOR_PIN A0  // Analog pin for thermistor
#define BUTTON_PIN 2        // Digital pin for button
#define LED_AUTO 3          // Digital pin for AUTO mode LED
#define LED_MANUAL 4        // Digital pin for MANUAL mode LED

#define TEMP_THRESHOLD 25  // Temperature threshold for fan activation in Celsius

bool manualMode = false;

void setup() {

  Serial.begin(9600);

  // Set pin modes
  pinMode(MOTOR_PIN, OUTPUT);
  pinMode(TEMP_SENSOR_PIN, INPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(LED_AUTO, OUTPUT);
  pinMode(LED_MANUAL, OUTPUT);

  // Initialize LEDs
  digitalWrite(LED_AUTO, HIGH);  // Auto mode is the default
  digitalWrite(LED_MANUAL, LOW);
}

void loop() {
  static bool lastButtonState = HIGH;  // Last state of the button

  // Check for button press
  bool currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState == LOW && lastButtonState == HIGH) {
    manualMode = !manualMode;  // Toggle mode
    // Update LEDs based on mode
    if (manualMode) {
      digitalWrite(LED_AUTO, LOW);
      digitalWrite(LED_MANUAL, HIGH);
    } else {
      digitalWrite(LED_AUTO, HIGH);
      digitalWrite(LED_MANUAL, LOW);
    }
    delay(200);  // Debounce delay
  }
  lastButtonState = currentButtonState;

  // Fan control logic
  if (manualMode) {
    analogWrite(MOTOR_PIN, 255);  // Full speed in manual mode
  } else {
    float voltage = analogRead(TEMP_SENSOR_PIN) * 5.0 / 1023.0;
    float temperature = voltageToTemperature(voltage);  // Convert voltage to temperature
    if (temperature > TEMP_THRESHOLD) {
      // Scale fan speed based on temperature
      analogWrite(MOTOR_PIN, map(temperature, TEMP_THRESHOLD, 40, 100, 255));
    } else {
      analogWrite(MOTOR_PIN, 0);  // Turn off the fan
    }
  }
}


// Convert voltage reading from thermistor to temperature in Celsius
float voltageToTemperature(float voltage) {
  // Define constants
  const float referenceResistor = 10000;  // the 'other' resistor
  const float beta = 3950;                // Beta value (Typical Value)
  const float nominalTemperature = 25;    // Nominal temperature for calculating the temperature coefficient
  const float nominalResistance = 10000;  // Resistance value at nominal temperature

  // Convert the reading to resistance
  float Rt = referenceResistor * (5.0 - voltage) / voltage;

  // Use the Beta parameter equation to calculate temperature in Kelvin
  float tempK = 1 / (((log(Rt / nominalResistance)) / beta) + (1 / (nominalTemperature + 273.15)));

  // Convert to Celsius
  float tempC = tempK - 273.15;

  // Print temperature in Celsius to the Serial Monitor
  Serial.print("Temp: ");
  Serial.print(tempC);
  Serial.println(" degree Celsius");

  // Convert to Fahrenheit
  // float tempF = tempC * 1.8 + 32;

  return tempC;
}

どのように動作しますか？

以下はコードのステップバイステップの説明です：

定数と変数の定義：

様々なハードウェア接続用のピンを定義するために #define を使用します。 TEMP_THRESHOLD は25°Cと定義され、これはファンを起動する温度のしきい値です。 manualMode：手動モードかどうかを示すブール変数。
setup()：

関連するピンのモード（出力、入力、プルアップ付き入力）を設定します。初期状態は自動モードなので、 LED_AUTO が点灯し、 LED_MANUAL は消灯しています。
loop()：

ボタンの状態を監視します。ボタンが押されると、モードが切り替わり、LEDの状態が変わります。手動モードでは、ファンは最大速度で稼働します。自動モードでは、まず温度センサーからの電圧値を読み取り、それを温度値に変換します。温度がしきい値を超えると、ファンの速度は温度に基づいて調整されます。
voltageToTemperature()：

温度センサーからの電圧値を摂氏の温度値に変換するための補助関数です。この関数は、サーミスタの標準式を使用して温度を推定します。戻り値は摂氏です。