Nota

Ciao, benvenuto nella community SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts su Facebook! Approfondisci Raspberry Pi, Arduino ed ESP32 con altri appassionati.

Perché unirsi?

• Supporto Esperto: Risolvi problemi post-vendita e sfide tecniche con l’aiuto della nostra community e del nostro team.

• Impara & Condividi: Scambia consigli e tutorial per migliorare le tue competenze.

• Anteprime Esclusive: Ottieni l’accesso anticipato agli annunci di nuovi prodotti e anteprime esclusive.

• Sconti Speciali: Goditi sconti esclusivi sui nostri prodotti più recenti.

• Promozioni e Concorsi Festivi: Partecipa a concorsi e promozioni festive.

👉 Pronto a esplorare e creare con noi? Clicca [Qui] e unisciti oggi stesso!

Ventilatore Intelligente

Questo progetto Arduino regola automaticamente la velocità del ventilatore per mantenere la temperatura entro un intervallo adeguato. Inoltre, gli utenti possono entrare in modalità manuale tramite un pulsante per far funzionare il ventilatore alla massima velocità.

Componenti Necessari

In questo progetto, abbiamo bisogno dei seguenti componenti.

È sicuramente conveniente acquistare un kit completo, ecco il link:

Nome	ELEMENTI IN QUESTO KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

Puoi anche acquistarli separatamente dai link sottostanti.

INTRODUZIONE COMPONENTI	LINK ACQUISTO
Arduino Uno R4 WiFi	-
Breadboard	ACQUISTA
Cavi Jumper	ACQUISTA
Resistenza	ACQUISTA
LED	ACQUISTA
Pulsante	ACQUISTA
Termistore	ACQUISTA
Motore DC	ACQUISTA
TA6586 - Chip Driver del Motore	-
Modulo di Alimentazione	-

Collegamenti

Nota

Per proteggere il Power Pack del Modulo di Alimentazione, caricalo completamente prima di utilizzarlo per la prima volta.

Schema Elettrico

Codice

Nota

• Puoi aprire il file 06_smart_fan.ino nel percorso elite-explorer-kit-main\fun_project\06_smart_fan direttamente.

• Oppure copia questo codice nell’Arduino IDE.

06_smart_fan.ino

/*
  This code controls a DC motor fan based on temperature readings from a thermistor. 
  It includes a manual override feature using a button. In automatic mode, the fan speed 
  is controlled according to the temperature. In manual mode, the fan runs at full speed. 
  LEDs are used to indicate the current mode (auto or manual).

  Board: Arduino Uno R4 
  Component: LED, button, thermistor, and DC motor.
*/

// Pin assignments
#define MOTOR_PIN 9         // PWM compatible pin for DC motor
#define TEMP_SENSOR_PIN A0  // Analog pin for thermistor
#define BUTTON_PIN 2        // Digital pin for button
#define LED_AUTO 3          // Digital pin for AUTO mode LED
#define LED_MANUAL 4        // Digital pin for MANUAL mode LED

#define TEMP_THRESHOLD 25  // Temperature threshold for fan activation in Celsius

bool manualMode = false;

void setup() {

  Serial.begin(9600);

  // Set pin modes
  pinMode(MOTOR_PIN, OUTPUT);
  pinMode(TEMP_SENSOR_PIN, INPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(LED_AUTO, OUTPUT);
  pinMode(LED_MANUAL, OUTPUT);

  // Initialize LEDs
  digitalWrite(LED_AUTO, HIGH);  // Auto mode is the default
  digitalWrite(LED_MANUAL, LOW);
}

void loop() {
  static bool lastButtonState = HIGH;  // Last state of the button

  // Check for button press
  bool currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState == LOW && lastButtonState == HIGH) {
    manualMode = !manualMode;  // Toggle mode
    // Update LEDs based on mode
    if (manualMode) {
      digitalWrite(LED_AUTO, LOW);
      digitalWrite(LED_MANUAL, HIGH);
    } else {
      digitalWrite(LED_AUTO, HIGH);
      digitalWrite(LED_MANUAL, LOW);
    }
    delay(200);  // Debounce delay
  }
  lastButtonState = currentButtonState;

  // Fan control logic
  if (manualMode) {
    analogWrite(MOTOR_PIN, 255);  // Full speed in manual mode
  } else {
    float voltage = analogRead(TEMP_SENSOR_PIN) * 5.0 / 1023.0;
    float temperature = voltageToTemperature(voltage);  // Convert voltage to temperature
    if (temperature > TEMP_THRESHOLD) {
      // Scale fan speed based on temperature
      analogWrite(MOTOR_PIN, map(temperature, TEMP_THRESHOLD, 40, 100, 255));
    } else {
      analogWrite(MOTOR_PIN, 0);  // Turn off the fan
    }
  }
}


// Convert voltage reading from thermistor to temperature in Celsius
float voltageToTemperature(float voltage) {
  // Define constants
  const float referenceResistor = 10000;  // the 'other' resistor
  const float beta = 3950;                // Beta value (Typical Value)
  const float nominalTemperature = 25;    // Nominal temperature for calculating the temperature coefficient
  const float nominalResistance = 10000;  // Resistance value at nominal temperature

  // Convert the reading to resistance
  float Rt = referenceResistor * (5.0 - voltage) / voltage;

  // Use the Beta parameter equation to calculate temperature in Kelvin
  float tempK = 1 / (((log(Rt / nominalResistance)) / beta) + (1 / (nominalTemperature + 273.15)));

  // Convert to Celsius
  float tempC = tempK - 273.15;

  // Print temperature in Celsius to the Serial Monitor
  Serial.print("Temp: ");
  Serial.print(tempC);
  Serial.println(" degree Celsius");

  // Convert to Fahrenheit
  // float tempF = tempC * 1.8 + 32;

  return tempC;
}

Come funziona?

Ecco una spiegazione passo-passo del codice:

1. Definizioni di Costanti e Variabili:

   Usa #define per definire i pin per vari collegamenti hardware. TEMP_THRESHOLD è definito come 25°C, che è la soglia di temperatura per avviare il ventilatore. manualMode: Una variabile booleana che indica se è in modalità manuale.

2. setup():

   Imposta la modalità per i pin rilevanti (output, input, input con pull-up). Inizialmente impostato su modalità automatica, quindi LED_AUTO è acceso mentre LED_MANUAL è spento.

3. loop():

   Monitora lo stato del pulsante. Quando il pulsante viene premuto, cambia modalità e cambia lo stato del LED. In modalità manuale, il ventilatore funziona alla massima velocità. In modalità automatica, il codice legge prima il valore di tensione dal sensore di temperatura e lo converte in un valore di temperatura. Se la temperatura supera la soglia, la velocità del ventilatore viene regolata in base alla temperatura.

4. voltageToTemperature():

   Questa è una funzione ausiliaria utilizzata per convertire il valore di tensione dal sensore di temperatura in un valore di temperatura (in Celsius). La funzione utilizza la formula standard per un termistore per stimare la temperatura. Il valore restituito è in gradi Celsius.