Nota

Ciao, benvenuto nella community SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts su Facebook! Approfondisci Raspberry Pi, Arduino ed ESP32 con altri appassionati.

Perché unirsi?

• Supporto Esperto: Risolvi problemi post-vendita e sfide tecniche con l’aiuto della nostra community e del nostro team.

• Impara & Condividi: Scambia consigli e tutorial per migliorare le tue competenze.

• Anteprime Esclusive: Ottieni l’accesso anticipato agli annunci di nuovi prodotti e anteprime esclusive.

• Sconti Speciali: Goditi sconti esclusivi sui nostri prodotti più recenti.

• Promozioni e Concorsi Festivi: Partecipa a concorsi e promozioni festive.

👉 Pronto a esplorare e creare con noi? Clicca [Qui] e unisciti oggi stesso!

GIOCO - Escape

Questo gioco si chiama «Escape». L’obiettivo del giocatore è inclinare il sensore MPU6050 per muovere un pixel sulla matrice LED e cercare di farlo passare attraverso un’apertura nel bordo della matrice (l’uscita).

Componenti Necessari

In questo progetto, abbiamo bisogno dei seguenti componenti.

È sicuramente conveniente acquistare un kit completo, ecco il link:

Nome	ELEMENTI IN QUESTO KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

Puoi anche acquistarli separatamente dai link sottostanti.

INTRODUZIONE COMPONENTI	LINK ACQUISTO
Arduino Uno R4 WiFi	-
Cavi Jumper	ACQUISTA
Modulo IMU GY-87	-

Collegamenti

Schema Elettrico

Codice

Nota

• Puoi aprire il file 11_escape_square.ino nel percorso elite-explorer-kit-main\fun_project\11_escape_square direttamente.

• Oppure copia questo codice nell’Arduino IDE.

Nota

Per installare la libreria, usa l’Arduino Library Manager e cerca «Adafruit MPU6050» e installala.

11_escape_square.ino

/*
  The code utilizes an Arduino Uno and a GY-87 IMU module to create the "Escape" game. 
  The goal is for the player to tilt the MPU6050 sensor, which controls the movement 
  of a pixel on the LED matrix. The objective is to guide the pixel through an opening 
  in the border of the matrix (the exit). Each successful passage through the opening 
  raises the game level.

  Board: Arduino Uno R4 
  Component: GY-87 IMU module
  Library: https://github.com/adafruit/Adafruit_MPU6050  (Adafruit MPU6050 by Adafruit)
*/

// Include necessary libraries
#include "Arduino_LED_Matrix.h"
#include <Wire.h>
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>

// Create instances of sensor and matrix
Adafruit_MPU6050 mpu;
ArduinoLEDMatrix matrix;
byte frame[8][12];

int gapStart = 0;
int side = 0;  // 0: top, 1: right, 2: bottom, 3: left

int pixelX = 4;  // Initial position of the pixel in the center
int pixelY = 3;
int level =0;
bool pass = false;

unsigned long gapLastUpdate = 0;
unsigned long pixelLastUpdate = 0;

void setup() {
  //init matrix
  matrix.begin();
  drawSquareWithGap();
  matrix.loadPixels((uint8_t*)frame, 8 * 12);
  matrix.renderFrame(0);

  //init mpu6050
  Serial.begin(9600);
  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1) {
      delay(10);
    }
  }
  mpu.setAccelerometerRange(MPU6050_RANGE_2_G);
}

void loop() {
  // movePixelBasedOnMPU();
  // moveGap();

  unsigned long currentMillis = millis();
  
  if (currentMillis - pixelLastUpdate >= 200) {
    movePixelBasedOnMPU();
    checkPixelPosition();
    pixelLastUpdate = currentMillis;
  }
  
  if (currentMillis - gapLastUpdate >= 1020-level*100) {
    moveGap();
    gapLastUpdate = currentMillis;
  }
  
  matrix.loadPixels((uint8_t*)frame, 8 * 12);
  matrix.renderFrame(0);
  if (pass){
    delay(1500); //delay for show
    pass=false;
    resetPixel();
  }
}




void drawSquareWithGap() {
  memset(frame, 0, 8 * 12);  // Clear the frame

  for (int i = 0; i < 8; i++) {
    for (int j = 0; j < 8; j++) {
      if (i == 0 || i == 7 || j == 0 || j == 7) {
        frame[i][j] = 1;  // Set border pixel
      }
    }
  }

  createGap();

  // Redraw the pixel after drawing the square and gap
  frame[pixelY][pixelX] = 1;
}

void createGap() {
  switch (side) {
    case 0:  // top
      frame[0][gapStart] = 0;
      frame[0][gapStart + 1] = 0;
      // frame[0][gapStart + 2] = 0;
      break;
    case 1:  // right
      frame[gapStart][7] = 0;
      frame[gapStart + 1][7] = 0;
      // frame[gapStart + 2][7] = 0;
      break;
    case 2:  // bottom
      frame[7][7 - gapStart] = 0;
      frame[7][6 - gapStart] = 0;
      // frame[7][5 - gapStart] = 0;
      break;
    case 3:  // left
      frame[7 - gapStart][0] = 0;
      frame[6 - gapStart][0] = 0;
      // frame[5 - gapStart][0] = 0;
      break;
  }
}

void moveGap() {
  gapStart++;

  if (side == 0 && gapStart > 5) {
    gapStart = 0;
    side = 1;
  } else if (side == 1 && gapStart > 5) {
    gapStart = 0;
    side = 2;
  } else if (side == 2 && gapStart > 5) {
    gapStart = 0;
    side = 3;
  } else if (side == 3 && gapStart > 5) {
    gapStart = 0;
    side = 0;
  }

  drawSquareWithGap();  // Redraw the square with the moved gap
}


void movePixelBasedOnMPU() {
  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);

  frame[pixelY][pixelX] = 0;  // Clear current pixel

  if (a.acceleration.x > 1.0) {
    // pixelY++;
    pixelY--;
  } else if (a.acceleration.x < -1.0) {
    // pixelY--;
    pixelY++;
  }

  if (a.acceleration.y > 1.0) {
    pixelX--;
  } else if (a.acceleration.y < -1.0) {
    pixelX++;
  }

  if (pixelX > 7 || pixelX < 0 || pixelY > 7 || pixelY < 0 || frame[pixelY][pixelX] == 1) {
    resetPixel();
  } else {
    frame[pixelY][pixelX] = 1;
  }
}

void resetPixel() {
  pixelX = 4;
  pixelY = 3;
  frame[pixelY][pixelX] = 1;
}

void checkPixelPosition() {
  bool isOnGap = false;

  // Check if the pixel is on the gap
  switch (side) {
    case 0: // top
      if (pixelY == 0 && pixelX >= gapStart && pixelX <= gapStart + 2) isOnGap = true;
      break;
    case 1: // right
      if (pixelX == 7 && pixelY >= gapStart && pixelY <= gapStart + 2) isOnGap = true;
      break;
    case 2: // bottom
      if (pixelY == 7 && pixelX >= 5 - gapStart && pixelX <= 7 - gapStart) isOnGap = true;
      break;
    case 3: // left
      if (pixelX == 0 && pixelY >= 5 - gapStart && pixelY <= 7 - gapStart) isOnGap = true;
      break;
  }

  if (isOnGap) {
    if (level<=10){ level++;}
    else {level=0;}
    pass = true;
  } 

  // Optionally, you can print out the level for debugging
  // Serial.println("Level: " + String(level));
}

Come funziona?

Ecco una spiegazione dettagliata del codice:

1. Importazione Librerie e Variabili Globali:

   Le librerie importate includono la matrice LED, Wire (per la comunicazione I2C), MPU6050 (sensore di movimento) e la libreria Adafruit_Sensor. Inizializzazione degli oggetti MPU6050 e matrice LED. Definizione di variabili globali come pixelX e pixelY (posizione del pixel), gapStart e side (posizione iniziale del gap e lato), level (livello di difficoltà del gioco) e altre.

2. setup():

   Inizializza la matrice LED e disegna la matrice con il gap. Inizializza la comunicazione seriale e controlla se il sensore MPU6050 si avvia correttamente, impostando il suo intervallo di accelerazione a 2g.

3. loop():

   Aggiorna periodicamente la posizione del pixel in base alle letture del sensore MPU6050. Sposta periodicamente la posizione del gap. Carica il nuovo layout del pixel e lo visualizza sulla matrice LED. Controlla se il pixel è passato attraverso il gap. Se lo è, ritarda di 1,5 secondi per visualizzare il successo, aumenta la difficoltà del gioco e ripristina la posizione del pixel.

4. Altre Funzioni:

   • drawSquareWithGap(): Disegna un bordo 8x8 e crea un gap al suo interno.

   • createGap(): Crea un gap di lunghezza 2 sul lato specificato.

   • moveGap(): Sposta la posizione del gap in base al lato corrente e a gapStart, cambiando lato quando necessario.

   • movePixelBasedOnMPU(): Legge i dati di accelerazione dal sensore MPU6050. Sposta la posizione del pixel in base ai dati di accelerazione (reimpostando se il pixel esce dai limiti o entra nelle pareti).

   • resetPixel(): Reimposta la posizione del pixel al centro della matrice.

   • checkPixelPosition(): Controlla se il pixel si trova sul gap. Se lo è, aumenta il livello di difficoltà del gioco e imposta il flag di passaggio su true.