Nota

Ciao, benvenuto nella community SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts su Facebook! Approfondisci Raspberry Pi, Arduino ed ESP32 con altri appassionati.

Perché unirsi?

• Supporto Esperto: Risolvi problemi post-vendita e sfide tecniche con l’aiuto della nostra community e del nostro team.

• Impara & Condividi: Scambia consigli e tutorial per migliorare le tue competenze.

• Anteprime Esclusive: Ottieni l’accesso anticipato agli annunci di nuovi prodotti e anteprime esclusive.

• Sconti Speciali: Goditi sconti esclusivi sui nostri prodotti più recenti.

• Promozioni e Concorsi Festivi: Partecipa a concorsi e promozioni festive.

👉 Pronto a esplorare e creare con noi? Clicca [Qui] e unisciti oggi stesso!

Pattumiera Intelligente

Questo codice Arduino è progettato per controllare una pattumiera intelligente. Quando un oggetto è entro 20 centimetri di distanza davanti alla pattumiera, il coperchio si apre automaticamente. Questo progetto utilizza un servo motore SG90 e un sensore di distanza ultrasonico HC-SR04.

Componenti Necessari

In questo progetto, abbiamo bisogno dei seguenti componenti.

È sicuramente conveniente acquistare un kit completo, ecco il link:

Nome	ELEMENTI IN QUESTO KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

Puoi anche acquistarli separatamente dai link sottostanti.

INTRODUZIONE COMPONENTI	LINK ACQUISTO
Arduino Uno R4 WiFi	-
Breadboard	ACQUISTA
Cavi Jumper	ACQUISTA
Modulo Ultrasonico	ACQUISTA
Servo	ACQUISTA

Collegamenti

Schema Elettrico

Codice

Nota

• Puoi aprire il file 07_smart_trash_can.ino nel percorso elite-explorer-kit-main\fun_project\07_smart_trash_can direttamente.

• Oppure copia questo codice nell’Arduino IDE.

07_smart_trash_can.ino

/*
  This is an Arduino code for a smart trash can that automatically opens its lid when an object comes within 30cm of it.
  
  This Arduino code controls an SG90 servo motor based on readings from an ultrasonic distance sensor. 
  The distance is measured three times, and the average is computed. If the averaged distance is less 
  than or equal to 20, the servo rotates to an open angle of 180 degrees; otherwise, it returns to a 
  closed position of 0 degrees after a one-second delay. 

  Board: Arduino Uno R4 (or R3)
  Component: Servo motor and Ultrasonic distance Sensor
*/

#include <Servo.h>

// Set up the servo motor parameters
Servo servo;
const int servoPin = 9;
const int openAngle = 0;
const int closeAngle = 90;

// Set up the ultrasonic sensor parameters
const int trigPin = 5;
const int echoPin = 6;
long distance, averageDistance;
long averDist[3];

// Distance threshold in centimeters
const int distanceThreshold = 20;

void setup() {
  // Initialize serial communication with the computer at 9600 baud rate
  Serial.begin(9600);

  // Configure the trigger and echo pins of the ultrasonic sensor
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  // Attach the servo to its control pin and set its initial position
  servo.attach(servoPin);
  servo.write(closeAngle);
  delay(100);
  servo.detach();  // Detach the servo to save power when not in use
}

void loop() {
  // Measure the distance three times
  for (int i = 0; i <= 2; i++) {
    distance = readDistance();
    averDist[i] = distance;
    delay(10);
  }

  // Calculate the average distance
  averageDistance = (averDist[0] + averDist[1] + averDist[2]) / 3;
  Serial.println(averageDistance);

  // Control the servo based on the averaged distance
  if (averageDistance <= distanceThreshold) {
    servo.attach(servoPin);  // Reattach the servo before sending a command
    delay(1);
    servo.write(openAngle);  // Rotate the servo to the open position
    delay(3500);
  } else {
    servo.write(closeAngle);  // Rotate the servo back to the closed position
    delay(1000);
    servo.detach();  // Detach the servo to save power when not in use
  }
}

// Function to read the sensor data and calculate the distance
float readDistance() {
  // Send a pulse on the trigger pin of the ultrasonic sensor
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  // Measure the pulse width of the echo pin and calculate the distance value
  float distance = pulseIn(echoPin, HIGH) / 58.00;  // Formula: (340m/s * 1us) / 2
  return distance;
}

Come funziona?

Ecco una spiegazione passo-passo del codice:

1. Importa Librerie e Definisci Costanti/Variabili:

   La libreria Servo.h viene importata per controllare il servo motore SG90. I parametri per il servo motore, il sensore ultrasonico e altre costanti e variabili necessarie sono definiti.

2. setup():

   Inizializza la comunicazione seriale con il computer a un baud rate di 9600. Configura i pin di trigger ed echo del sensore ultrasonico. Collega il servo motore al suo pin di controllo e imposta la sua posizione iniziale all’angolo di chiusura. Dopo aver impostato l’angolo, il servo motore viene disconnesso per risparmiare energia.

3. loop():

   Misura la distanza tre volte e memorizza i valori di ciascuna misurazione. Calcola la distanza media dalle tre misurazioni. Se la distanza media è minore o uguale a 20 centimetri (soglia di distanza definita), il servo motore ruota all’angolo di apertura (0 gradi). Altrimenti, il servo motore ritorna alla posizione di chiusura (90 gradi) dopo un ritardo di un secondo. Il servo motore viene disconnesso quando non in uso per conservare energia.

4. readDistance():

   Invia un impulso al pin di trigger del sensore ultrasonico. Misura la durata dell’impulso del pin di echo e calcola il valore della distanza. Questo calcolo utilizza la velocità del suono nell’aria per determinare la distanza basata sul tempo dell’impulso.