Note

Hello, welcome to the SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts Community on Facebook! Dive deeper into Raspberry Pi, Arduino, and ESP32 with fellow enthusiasts.

Why Join?

Expert Support: Solve post-sale issues and technical challenges with help from our community and team.
Learn & Share: Exchange tips and tutorials to enhance your skills.
Exclusive Previews: Get early access to new product announcements and sneak peeks.
Special Discounts: Enjoy exclusive discounts on our newest products.
Festive Promotions and Giveaways: Take part in giveaways and holiday promotions.

👉 Ready to explore and create with us? Click [here] and join today!

Smart Fan

This Arduino project automatically adjusts the fan’s speed to maintain the temperature within a suitable range. Additionally, users can enter manual mode through a button to operate the fan at maximum speed.

Required Components

In this project, we need the following components.

It’s definitely convenient to buy a whole kit, here’s the link:

Name	ITEMS IN THIS KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

You can also buy them separately from the links below.

COMPONENT INTRODUCTION	PURCHASE LINK
Arduino Uno R4 WiFi	-
Breadboard	BUY
Jumper Wires	BUY
Resistor	BUY
LED	BUY
Button	BUY
Thermistor	BUY
DC Motor	BUY
TA6586 - Motor Driver Chip	-
Power Supply Module	-

Wiring

Note

The motor requires more power during operation, so please keep the power module connected to a charging cable when in use.

Schematic

Code

Note

You can open the file 06_smart_fan.ino under the path of elite-explorer-kit-main\fun_project\06_smart_fan directly.
Or copy this code into Arduino IDE.

06_smart_fan.ino

/*
  This code controls a DC motor fan based on temperature readings from a thermistor. 
  It includes a manual override feature using a button. In automatic mode, the fan speed 
  is controlled according to the temperature. In manual mode, the fan runs at full speed. 
  LEDs are used to indicate the current mode (auto or manual).

  Board: Arduino Uno R4 
  Component: LED, button, thermistor, and DC motor.
*/

// Pin assignments
#define MOTOR_PIN 9         // PWM compatible pin for DC motor
#define TEMP_SENSOR_PIN A0  // Analog pin for thermistor
#define BUTTON_PIN 2        // Digital pin for button
#define LED_AUTO 3          // Digital pin for AUTO mode LED
#define LED_MANUAL 4        // Digital pin for MANUAL mode LED

#define TEMP_THRESHOLD 25  // Temperature threshold for fan activation in Celsius

bool manualMode = false;

void setup() {

  Serial.begin(9600);

  // Set pin modes
  pinMode(MOTOR_PIN, OUTPUT);
  pinMode(TEMP_SENSOR_PIN, INPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(LED_AUTO, OUTPUT);
  pinMode(LED_MANUAL, OUTPUT);

  // Initialize LEDs
  digitalWrite(LED_AUTO, HIGH);  // Auto mode is the default
  digitalWrite(LED_MANUAL, LOW);
}

void loop() {
  static bool lastButtonState = HIGH;  // Last state of the button

  // Check for button press
  bool currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState == LOW && lastButtonState == HIGH) {
    manualMode = !manualMode;  // Toggle mode
    // Update LEDs based on mode
    if (manualMode) {
      digitalWrite(LED_AUTO, LOW);
      digitalWrite(LED_MANUAL, HIGH);
    } else {
      digitalWrite(LED_AUTO, HIGH);
      digitalWrite(LED_MANUAL, LOW);
    }
    delay(200);  // Debounce delay
  }
  lastButtonState = currentButtonState;

  // Fan control logic
  if (manualMode) {
    analogWrite(MOTOR_PIN, 255);  // Full speed in manual mode
  } else {
    float voltage = analogRead(TEMP_SENSOR_PIN) * 5.0 / 1023.0;
    float temperature = voltageToTemperature(voltage);  // Convert voltage to temperature
    if (temperature > TEMP_THRESHOLD) {
      // Scale fan speed based on temperature
      analogWrite(MOTOR_PIN, map(temperature, TEMP_THRESHOLD, 40, 100, 255));
    } else {
      analogWrite(MOTOR_PIN, 0);  // Turn off the fan
    }
  }
}


// Convert voltage reading from thermistor to temperature in Celsius
float voltageToTemperature(float voltage) {
  // Define constants
  const float referenceResistor = 10000;  // the 'other' resistor
  const float beta = 3950;                // Beta value (Typical Value)
  const float nominalTemperature = 25;    // Nominal temperature for calculating the temperature coefficient
  const float nominalResistance = 10000;  // Resistance value at nominal temperature

  // Convert the reading to resistance
  float Rt = referenceResistor * (5.0 - voltage) / voltage;

  // Use the Beta parameter equation to calculate temperature in Kelvin
  float tempK = 1 / (((log(Rt / nominalResistance)) / beta) + (1 / (nominalTemperature + 273.15)));

  // Convert to Celsius
  float tempC = tempK - 273.15;

  // Print temperature in Celsius to the Serial Monitor
  Serial.print("Temp: ");
  Serial.print(tempC);
  Serial.println(" degree Celsius");

  // Convert to Fahrenheit
  // float tempF = tempC * 1.8 + 32;

  return tempC;
}

How it works?

Here is a step-by-step explanation of the code:

Constants and Variable Definitions:

Use #define to define the pins for various hardware connections. TEMP_THRESHOLD is defined as 25°C, which is the temperature threshold to start the fan. manualMode: A boolean variable that indicates whether it is in manual mode.
setup():

Set the mode for relevant pins (output, input, input with pull-up). Initially set to automatic mode, so LED_AUTO is lit while LED_MANUAL is off.
loop():

Monitor the button’s state. When the button is pressed, it toggles the mode and changes the LED’s status. In manual mode, the fan operates at maximum speed. In automatic mode, the code first reads the voltage value from the temperature sensor and converts it to a temperature value. If the temperature exceeds the threshold, the fan’s speed is adjusted based on the temperature.
voltageToTemperature():

This is an auxiliary function used to convert the voltage value from the temperature sensor into a temperature value (in Celsius). The function uses the standard formula for a thermistor to estimate the temperature. The return value is in degrees Celsius.