Note

Hello, welcome to the SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts Community on Facebook! Dive deeper into Raspberry Pi, Arduino, and ESP32 with fellow enthusiasts.

Why Join?

• Expert Support: Solve post-sale issues and technical challenges with help from our community and team.

• Learn & Share: Exchange tips and tutorials to enhance your skills.

• Exclusive Previews: Get early access to new product announcements and sneak peeks.

• Special Discounts: Enjoy exclusive discounts on our newest products.

• Festive Promotions and Giveaways: Take part in giveaways and holiday promotions.

👉 Ready to explore and create with us? Click [here] and join today!

Smart Can

This is an Arduino code designed to control a smart garbage can. When an object is within a 20-centimeter range in front of the garbage can, its lid automatically opens. This project utilizes an SG90 servo motor and an HC-SR04 ultrasonic distance sensor.

Required Components

In this project, we need the following components.

It’s definitely convenient to buy a whole kit, here’s the link:

Name	ITEMS IN THIS KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

You can also buy them separately from the links below.

COMPONENT INTRODUCTION	PURCHASE LINK
Arduino Uno R4 WiFi	-
Breadboard	BUY
Jumper Wires	BUY
Ultrasonic Module	BUY
Servo	BUY

Wiring

Schematic

Code

Note

• You can open the file 07_smart_trash_can.ino under the path of elite-explorer-kit-main\fun_project\07_smart_trash_can directly.

• Or copy this code into Arduino IDE.

07_smart_trash_can.ino

/*
  This is an Arduino code for a smart trash can that automatically opens its lid when an object comes within 30cm of it.
  
  This Arduino code controls an SG90 servo motor based on readings from an ultrasonic distance sensor. 
  The distance is measured three times, and the average is computed. If the averaged distance is less 
  than or equal to 20, the servo rotates to an open angle of 180 degrees; otherwise, it returns to a 
  closed position of 0 degrees after a one-second delay. 

  Board: Arduino Uno R4 (or R3)
  Component: Servo motor and Ultrasonic distance Sensor
*/

#include <Servo.h>

// Set up the servo motor parameters
Servo servo;
const int servoPin = 9;
const int openAngle = 0;
const int closeAngle = 90;

// Set up the ultrasonic sensor parameters
const int trigPin = 5;
const int echoPin = 6;
long distance, averageDistance;
long averDist[3];

// Distance threshold in centimeters
const int distanceThreshold = 20;

void setup() {
  // Initialize serial communication with the computer at 9600 baud rate
  Serial.begin(9600);

  // Configure the trigger and echo pins of the ultrasonic sensor
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  // Attach the servo to its control pin and set its initial position
  servo.attach(servoPin);
  servo.write(closeAngle);
  delay(100);
  servo.detach();  // Detach the servo to save power when not in use
}

void loop() {
  // Measure the distance three times
  for (int i = 0; i <= 2; i++) {
    distance = readDistance();
    averDist[i] = distance;
    delay(10);
  }

  // Calculate the average distance
  averageDistance = (averDist[0] + averDist[1] + averDist[2]) / 3;
  Serial.println(averageDistance);

  // Control the servo based on the averaged distance
  if (averageDistance <= distanceThreshold) {
    servo.attach(servoPin);  // Reattach the servo before sending a command
    delay(1);
    servo.write(openAngle);  // Rotate the servo to the open position
    delay(3500);
  } else {
    servo.write(closeAngle);  // Rotate the servo back to the closed position
    delay(1000);
    servo.detach();  // Detach the servo to save power when not in use
  }
}

// Function to read the sensor data and calculate the distance
float readDistance() {
  // Send a pulse on the trigger pin of the ultrasonic sensor
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  // Measure the pulse width of the echo pin and calculate the distance value
  float distance = pulseIn(echoPin, HIGH) / 58.00;  // Formula: (340m/s * 1us) / 2
  return distance;
}

How it works?

Here is a step-by-step explanation of the code:

1. Import Libraries and Define Constants/Variables:

   The Servo.h library is imported for controlling the SG90 servo motor. Parameters for the servo motor, ultrasonic sensor, and other required constants and variables are defined.

2. setup():

   Initialize serial communication with the computer at a baud rate of 9600. Configure the trigger and echo pins of the ultrasonic sensor. Attach the servo motor to its control pin and set its initial position to the closed angle. After setting the angle, the servo motor is detached to save power.

3. loop():

   Measure distance three times and store the values of each measurement. Calculate the average distance from the three measurements. If the average distance is less than or equal to 20 centimeters (defined distance threshold), the servo motor rotates to the open angle (0 degrees). Otherwise, the servo motor returns to the closed position (90 degrees) after a one-second delay. The servo motor is detached when not in use to conserve power.

4. readDistance():

   Send a pulse to the trigger pin of the ultrasonic sensor. Measure the pulse width of the echo pin and calculate the distance value. This calculation uses the speed of sound in the air to compute distance based on pulse time.