Bemerkung

Hallo und willkommen in der SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasten-Gemeinschaft auf Facebook! Tauchen Sie tiefer ein in die Welt von Raspberry Pi, Arduino und ESP32 mit anderen Enthusiasten.

Warum beitreten?

• Expertenunterstützung: Lösen Sie Nachverkaufsprobleme und technische Herausforderungen mit Hilfe unserer Gemeinschaft und unseres Teams.

• Lernen & Teilen: Tauschen Sie Tipps und Anleitungen aus, um Ihre Fähigkeiten zu verbessern.

• Exklusive Vorschauen: Erhalten Sie frühzeitigen Zugang zu neuen Produktankündigungen und exklusiven Einblicken.

• Spezialrabatte: Genießen Sie exklusive Rabatte auf unsere neuesten Produkte.

• Festliche Aktionen und Gewinnspiele: Nehmen Sie an Gewinnspielen und Feiertagsaktionen teil.

👉 Sind Sie bereit, mit uns zu erkunden und zu erschaffen? Klicken Sie auf [ hier ] und treten Sie heute bei!

Smarter Ventilator

Dieses Arduino-Projekt passt die Geschwindigkeit des Ventilators automatisch an, um die Temperatur in einem geeigneten Bereich zu halten. Zusätzlich können Benutzer über einen Knopf in den manuellen Modus wechseln und den Ventilator mit maximaler Geschwindigkeit betreiben.

Benötigte Komponenten

Für dieses Projekt benötigen wir die folgenden Komponenten.

Es ist definitiv praktisch, ein ganzes Kit zu kaufen, hier ist der Link:

Name	ARTIKEL IN DIESEM KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

Sie können sie auch einzeln über die untenstehenden Links kaufen.

KOMPONENTENBESCHREIBUNG	KAUF-LINK
Arduino Uno R4 WiFi	-
Steckbrett	KAUFEN
Jumperkabel	KAUFEN
Widerstand	KAUFEN
LED	KAUFEN
Knopf	KAUFEN
Thermistor	KAUFEN
Gleichstrommotor	KAUFEN
TA6586 - Motorsteuerungs-Chip	-
Stromversorgungsmodul	-

Verdrahtung

Schaltplan

Code

Bemerkung

• Sie können die Datei 06_smart_fan.ino direkt unter dem Pfad elite-explorer-kit-main\fun_project\06_smart_fan öffnen.

• Oder kopieren Sie diesen Code in die Arduino IDE.

06_smart_fan.ino

/*
  This code controls a DC motor fan based on temperature readings from a thermistor. 
  It includes a manual override feature using a button. In automatic mode, the fan speed 
  is controlled according to the temperature. In manual mode, the fan runs at full speed. 
  LEDs are used to indicate the current mode (auto or manual).

  Board: Arduino Uno R4 
  Component: LED, button, thermistor, and DC motor.
*/

// Pin assignments
#define MOTOR_PIN 9         // PWM compatible pin for DC motor
#define TEMP_SENSOR_PIN A0  // Analog pin for thermistor
#define BUTTON_PIN 2        // Digital pin for button
#define LED_AUTO 3          // Digital pin for AUTO mode LED
#define LED_MANUAL 4        // Digital pin for MANUAL mode LED

#define TEMP_THRESHOLD 25  // Temperature threshold for fan activation in Celsius

bool manualMode = false;

void setup() {

  Serial.begin(9600);

  // Set pin modes
  pinMode(MOTOR_PIN, OUTPUT);
  pinMode(TEMP_SENSOR_PIN, INPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(LED_AUTO, OUTPUT);
  pinMode(LED_MANUAL, OUTPUT);

  // Initialize LEDs
  digitalWrite(LED_AUTO, HIGH);  // Auto mode is the default
  digitalWrite(LED_MANUAL, LOW);
}

void loop() {
  static bool lastButtonState = HIGH;  // Last state of the button

  // Check for button press
  bool currentButtonState = digitalRead(BUTTON_PIN);
  if (currentButtonState == LOW && lastButtonState == HIGH) {
    manualMode = !manualMode;  // Toggle mode
    // Update LEDs based on mode
    if (manualMode) {
      digitalWrite(LED_AUTO, LOW);
      digitalWrite(LED_MANUAL, HIGH);
    } else {
      digitalWrite(LED_AUTO, HIGH);
      digitalWrite(LED_MANUAL, LOW);
    }
    delay(200);  // Debounce delay
  }
  lastButtonState = currentButtonState;

  // Fan control logic
  if (manualMode) {
    analogWrite(MOTOR_PIN, 255);  // Full speed in manual mode
  } else {
    float voltage = analogRead(TEMP_SENSOR_PIN) * 5.0 / 1023.0;
    float temperature = voltageToTemperature(voltage);  // Convert voltage to temperature
    if (temperature > TEMP_THRESHOLD) {
      // Scale fan speed based on temperature
      analogWrite(MOTOR_PIN, map(temperature, TEMP_THRESHOLD, 40, 100, 255));
    } else {
      analogWrite(MOTOR_PIN, 0);  // Turn off the fan
    }
  }
}


// Convert voltage reading from thermistor to temperature in Celsius
float voltageToTemperature(float voltage) {
  // Define constants
  const float referenceResistor = 10000;  // the 'other' resistor
  const float beta = 3950;                // Beta value (Typical Value)
  const float nominalTemperature = 25;    // Nominal temperature for calculating the temperature coefficient
  const float nominalResistance = 10000;  // Resistance value at nominal temperature

  // Convert the reading to resistance
  float Rt = referenceResistor * (5.0 - voltage) / voltage;

  // Use the Beta parameter equation to calculate temperature in Kelvin
  float tempK = 1 / (((log(Rt / nominalResistance)) / beta) + (1 / (nominalTemperature + 273.15)));

  // Convert to Celsius
  float tempC = tempK - 273.15;

  // Print temperature in Celsius to the Serial Monitor
  Serial.print("Temp: ");
  Serial.print(tempC);
  Serial.println(" degree Celsius");

  // Convert to Fahrenheit
  // float tempF = tempC * 1.8 + 32;

  return tempC;
}

Wie funktioniert des?

Hier ist eine schrittweise Erklärung des Codes:

1. Konstanten- und Variablendefinitionen:

   Verwenden Sie #define, um die Pins für verschiedene Hardwareverbindungen zu definieren. TEMP_THRESHOLD ist als 25°C definiert, was die Temperaturschwelle für den Start des Ventilators ist. manualMode: Eine boolesche Variable, die angibt, ob sich das Gerät im manuellen Modus befindet.

2. setup():

   Stellen Sie den Modus für relevante Pins ein (Ausgang, Eingang, Eingang mit Pull-up). Anfangs auf automatischen Modus eingestellt, sodass LED_AUTO leuchtet, während LED_MANUAL ausgeschaltet ist.

3. loop():

   Überwachen Sie den Zustand des Knopfs. Wenn der Knopf gedrückt wird, wechselt er den Modus und ändert den Status der LED. Im manuellen Modus arbeitet der Ventilator mit maximaler Geschwindigkeit. Im automatischen Modus liest der Code zuerst den Spannungswert vom Temperatursensor und wandelt ihn in einen Temperaturwert um. Wenn die Temperatur die Schwelle überschreitet, wird die Geschwindigkeit des Ventilators anhand der Temperatur eingestellt.

4. voltageToTemperature():

   Dies ist eine Hilfsfunktion, die verwendet wird, um den Spannungswert vom Temperatursensor in einen Temperaturwert (in Celsius) umzuwandeln. Die Funktion verwendet die Standardformel für einen Thermistor, um die Temperatur zu schätzen. Der Rückgabewert ist in Grad Celsius.