注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。
学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。
独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。
特別割引：最新製品の独占割引をお楽しみください。
祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

WeatherTime スクリーン

このスケッチはWi-Fiネットワークに接続し、毎分OpenWeatherMapから天気データを取得し、NTPサーバーから現在時刻を取得し、OLEDスクリーンに日付、時刻、天気情報を表示します。

必要なコンポーネント

このプロジェクトには以下のコンポーネントが必要です。

全体のキットを購入すると便利です。こちらがリンクです：

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

以下のリンクから別々に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ジャンパーワイヤー	購入
OLEDディスプレイモジュール	購入

配線図

回路図

../_images/06_weather_oled_schematic.png

OpenWeather

OpenWeather APIキーの取得

OpenWeather は、OpenWeather Ltdが所有するオンラインサービスで、API経由でグローバルな天気データを提供しています。これには、現在の天気データ、予報、ナウキャスト、歴史的天気データが任意の地理的位置に含まれます。

OpenWeatherにログインするか、アカウントを作成します。
ナビゲーションバーからAPIページに移動します。
Current Weather Data を見つけて、サブスクライブをクリックします。
Current weather and forecasts collection の下で、適切なサービスにサブスクライブします。私たちのプロジェクトでは、Freeで十分です。
API keys ページからキーをコピーします。

それを arduino_secrets.h にコピーします。

#define SECRET_SSID "<SSID>"        // your network SSID (name)
#define SECRET_PASS "<PASSWORD>"        // your network password
#define API_KEY "<OpenWeather_API_KEY>"
#define LOCATION "<YOUR CITY>"

あなたの場所のタイムゾーンを設定します。

スウェーデンの首都ストックホルムを例に取ります。Googleで「stockholm timezone」と検索します。

検索結果で、「GMT+1」を見ることができますので、以下の関数のパラメータを 3600 * 1 秒に設定します。
```
timeClient.setTimeOffset(3600 * 1);   // Adjust for your time zone (this is +1 hour)
```

ライブラリのインストール

ライブラリをインストールするには、Arduinoライブラリマネージャーを使用し、「ArduinoMqttClient」、「FastLED」、「Adafruit GFX」、「Adafruit SSD1306」を検索してインストールします。

ArduinoJson.h：JSONデータ（openweathermapから取得されたデータ）を扱うために使用します。

NTPClient.h：リアルタイムの時間を取得するために使用します。

Adafruit_GFX.h、 Adafruit_SSD1306.h：OLEDモジュール用に使用します。

コードの実行

注釈

ファイル 06_weather_oled.ino を elite-explorer-kit-main\iot_project\06_weather_oled のパスから直接開くことができます。
または、このコードをArduino IDEにコピーしてください。

注釈

コード内で、SSIDとパスワードは arduino_secrets.h に格納されています。この例をアップロードする前に、自分のWiFiの認証情報でそれらを修正する必要があります。さらに、コードを共有または保存する際には、この情報を機密に保つためのセキュリティ対策を講じてください。

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)
#define API_KEY "your_key"
#define LOCATION "your_location"

06_weather_oled.ino

/*
  The code fetches and shows weather information such as temperature, humidity, pressure, 
  and wind details. This information is obtained from the OpenWeatherMap API through a WiFi 
  connection. The program initially connects to the WiFi network and retrieves the current 
  time from an NTP server. It then regularly sends HTTP requests to retrieve weather data 
  from the OpenWeatherMap API. Upon receiving a JSON response, it parses the data and displays 
  both the weather information and current time on the OLED screen.

  Board: Arduino Uno R4 WiFi
  Component: OLED
  Library: https://github.com/bblanchon/ArduinoJson (ArduinoJson by Benoit Blanchon)
           https://github.com/adafruit/Adafruit_SSD1306 (Adafruit SSD1306 by Adafruit)  
           https://github.com/adafruit/Adafruit-GFX-Library (Adafruit GFX Library by Adafruit) 
           https://github.com/arduino-libraries/NTPClient (NTPClient by Fabrice Weinberg) 
           
*/

#include "WiFiS3.h"
#include <ArduinoJson.h>  // JSON decoding library
#include "arduino_secrets.h"

// NTP client setup to get real-time data
#include <NTPClient.h>
#include <WiFiUdp.h>
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "pool.ntp.org");  // NTP server

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define SCREEN_WIDTH 128  // OLED display width, in pixels
#define SCREEN_HEIGHT 64  // OLED display height, in pixels
#define OLED_RESET 4      // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// WiFi credentials and server information
char ssid[] = SECRET_SSID;  // your network SSID (name)
char pass[] = SECRET_PASS;  // your network password
int status = WL_IDLE_STATUS;
char server[] = "api.openweathermap.org";  // name address for OWM (using DNS)

// Timing variables to manage update intervals
unsigned long lastConnectionTime = 0;               // last time you connected to the server, in milliseconds
const unsigned long postingInterval = 60L * 1000L;  // delay between updates, in milliseconds

// WiFi client for connecting to the API server
WiFiClient client;

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    status = WiFi.begin(ssid, pass);
    delay(5000);  // Wait 5 seconds before retrying
  }

  printWifiStatus();

  // Initialize and clear OLED display
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.display();
  display.clearDisplay();

  // Initialize and clear OLED display
  timeClient.begin();
  timeClient.setTimeOffset(3600 * 8);  // Adjust for your time zone (this is +8 hour)
}

void loop() {

  read_response();
  timeClient.update();

  // Check if it's time to send a new request
  if (!lastConnectionTime || millis() - lastConnectionTime > postingInterval) {
    httpRequest();
  }
}


void read_response() {
  uint32_t received_data_num = 0;
  String payload = "";
  bool jsonDetected = false;

  // Read data from the client connection
  while (client.available()) {
    /* actual data reception */
    char c = client.read();
    
    // for debug
    Serial.print(c);
    
    if ('{' == c) {
      jsonDetected = true;
    }
    if (jsonDetected) {
      payload += c;
    }
    received_data_num++;
  }
  if (jsonDetected) {
    /* print data to serial port */
    // Serial.print("data num : ");
    // Serial.println(received_data_num);
    // Serial.print("data : ");
    // Serial.println(payload);
    DynamicJsonDocument root(1024);
    DeserializationError error = deserializeJson(root, payload);
    if (error) {
      Serial.print("Deserialization failed with code: ");
      Serial.println(error.c_str());
      return;
    }

    String weather = (root["weather"][0]["main"]);
    float temp = (float)(root["main"]["temp"]) - 273.15;        // get temperature in °C
    int humidity = root["main"]["humidity"];                    // get humidity in %
    float pressure = (float)(root["main"]["pressure"]) / 1000;  // get pressure in bar
    float wind_speed = root["wind"]["speed"];                   // get wind speed in m/s
    int wind_degree = root["wind"]["deg"];                      // get wind degree in °

    // // print data
    // Serial.println("Temperature= " + String(temp) + " °C");
    // Serial.println("Humidity = " + String(humidity) + " %");
    // Serial.println("Pressure = " + String(pressure) + " bar");
    // Serial.println("Wind speed = " + String(wind_speed) + " m/s");
    // Serial.println("Wind degree = " + String(wind_degree) + " °");
    displayWeatherData(weather, temp, humidity, pressure, wind_speed);
  }
}


void httpRequest() {
  // close any connection before send a new request.
  client.stop();

  // Construct HTTP GET request for OpenWeatherMap API
  String httpRequest = "";
  httpRequest += "GET /data/2.5/weather?q=" LOCATION "&APPID=" API_KEY " HTTP/1.1";

  // if you get a connection, report back via serial:
  if (client.connect(server, 80)) {
    Serial.println("connected");
    // Make a HTTP request:
    client.println(httpRequest);
    client.println("Host: api.openweathermap.org");
    client.println("Connection: close");
    client.println();
    // note the time that the connection was made:
    lastConnectionTime = millis();
  } else {
    // if you couldn't make a connection:
    Serial.println("connection failed");
  }
}

void printWifiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}

void displayWeatherData(String weather, float temp, int humidity, float pressure, float wind_speed) {
  display.clearDisplay();
  display.setTextSize(1);               // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE);  // Draw white text
  display.setCursor(0, 0);              // Start at top-left corner

  // Display Day of the Week
  String daysOfTheWeek[7] = { "Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday" };
  display.print(daysOfTheWeek[timeClient.getDay()]);

  display.print(" ");
  if (timeClient.getHours() < 10) display.print("0");  // Add leading zero for hours < 10
  display.print(timeClient.getHours());
  display.print(":");
  if (timeClient.getMinutes() < 10) display.print("0");  // Add leading zero for minutes < 10
  display.println(timeClient.getMinutes());

  display.println();
  display.print(LOCATION);
  display.println(" " + weather);

  // Display Weather
  display.print("Temperature: ");
  display.print(temp);
  display.println(" C");

  display.print("Humidity: ");
  display.print(humidity);
  display.println(" %");

  display.print("Pressure: ");
  display.print(pressure);
  display.println(" bar");

  display.print("Wind: ");
  display.print(wind_speed);
  display.println(" m/s");

  display.display();
}

どのように動作するのか？

ライブラリと定義:
1. WiFiS3.h：これは、特定のWiFiモジュールやボードに特有のライブラリで、WiFi接続を管理します。
2. ArduinoJson.h：このライブラリはJSONデータのデコード（およびエンコード）に使用されます。
3. arduino_secrets.h：機密データ（WiFiの認証情報など）が格納されている別のファイルです。これは、認証情報をメインコードから外しておくための良い習慣です。
4. NTPClient & WiFiUdp：NTP（Network Time Protocol）サーバーから現在時刻を取得するために使用されます。
5. Adafruitライブラリ：OLEDディスプレイを管理するために使用されます。
6. さまざまなグローバル変数：これにはWiFiの認証情報、サーバーの詳細などが含まれ、スクリプト全体で使用されます。
setup():
1. シリアル通信を初期化します。
2. WiFiモジュールのファームウェアバージョンをチェックして印刷します。
3. 提供されたSSIDとパスワードを使用してWiFiネットワークに接続を試みます。
4. 接続されたWiFiのステータス（SSID、IP、信号強度）を印刷します。
5. OLEDディスプレイを初期化します。
6. NTPクライアントを開始して現在時刻を取得し、タイムオフセットを設定します（この場合は8時間で、特定のタイムゾーンに対応する可能性があります）。
read_response():
1. サーバーからの応答を読み取り、特にJSONデータ（ { and } で示される）を探します。
2. JSONデータが見つかった場合、データをデコードして、気温、湿度、気圧、風速、風向きなどの天気の詳細を抽出します。
3. OLEDスクリーンに天気情報を表示する displayWeatherData 関数を呼び出します。
httpRequest():
1. 既存の接続を閉じて、WiFiモジュールのソケットが空いていることを確認します。
2. OpenWeatherMapサーバーに接続を試みます。
3. 接続された場合、 LOCATION で定義された特定の場所（おそらく arduino_secrets.h または他の場所で定義）の天気データを取得するためにHTTP GETリクエストを送信します。
4. リクエストが行われた時間を記録します。
loop():
1. サーバーからの受信データを処理するために read_response 関数を呼び出します。
2. NTPサーバーから時刻を更新します。
3. 天気サーバーに別のリクエストを行う時刻かどうかをチェックします（ postingInterval に基づいて）。そうであれば、 httpRequest 関数を呼び出します。
printWifiStatus():
1. 接続されているネットワークのSSID。
2. ボードのローカルIPアドレス。
3. 信号強度（RSSI）。
displayWeatherData():
1. OLEDスクリーンをクリアします。
2. 現在の曜日を表示します。
3. 現在時刻をHH:MM形式で表示します。
4. 提供された天気データ（気温、湿度、気圧、風速）を表示します。