注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。
学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。
独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。
特別割引：最新製品の独占割引をお楽しみください。
祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

MQTTを使用したクラウドコールシステム

メッセージキューイングテレメトリートランスポート（MQTT）は、直感的なメッセージングプロトコルです。これは、インターネットオブシングス（IoT）の分野で最も広く使用されているメッセージングプロトコルでもあります。

MQTTプロトコルは、IoTデバイスがデータを交換する方法を定義します。イベント駆動型であり、Publish/Subscribeモデルを使用して相互に接続されます。送信者（パブリッシャー）と受信者（サブスクライバー）はトピックを介して通信します。デバイスは特定のトピックにメッセージを公開し、そのトピックにサブスクライブしているすべてのデバイスがメッセージを受け取ります。

このセクションでは、UNO R4、HiveMQ（無料の公開MQTTブローカーサービス）、および4つのボタンを使用してサービスベルシステムを作成します。4つのボタンのそれぞれがレストランのテーブルに対応し、顧客がボタンを押すと、HiveMQ上でどのテーブルにサービスが必要かを確認できます。

必要なコンポーネント

このプロジェクトには以下のコンポーネントが必要です。

全体のキットを購入すると便利です。こちらがリンクです：

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

以下のリンクから別々に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ブレッドボード	購入
ジャンパーワイヤー	購入
ボタン	購入

配線図

回路図

遊び方は？

HiveMQは、IoTデバイスへの迅速で効率的で信頼性の高いデータ転送を促進するMQTTブローカーおよびクライアントベースのメッセージングプラットフォームです。

Webブラウザで HiveMQ Web Client を開きます。
クライアントをデフォルトの公開プロキシに接続します。
Add New Topic Subscription をクリックします。
フォローしたいトピックを入力し、 Subscribe をクリックします。他のユーザーからのメッセージを受け取らないように、ここで設定したトピックがユニークであることを確認し、大文字と小文字の区別に注意してください。

この例のコードでは、トピックを SunFounder MQTT Test と設定しました。変更がある場合は、コード内のトピックがWebページで購読したトピックと一致していることを確認してください。

ライブラリのインストール

ライブラリをインストールするには、Arduinoライブラリマネージャーを使用し、「ArduinoMqttClient」と検索してインストールしてください。

ArduinoMqttClient.h：MQTT通信用に使用します。

コードの実行

注釈

ファイル 04_mqtt_button.ino を elite-explorer-kit-main\iot_project\04_mqtt_button のパスから直接開くことができます。
または、このコードをArduino IDEにコピーしてください。

注釈

コード内で、SSIDとパスワードは arduino_secrets.h に格納されています。この例をアップロードする前に、自分のWiFiの認証情報でそれらを修正する必要があります。さらに、コードを共有または保存する際には、この情報を機密に保つためのセキュリティ対策を講じてください。

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)

04_mqtt_button.ino

/*
  The code is designed for an Arduino Uno R4 WiFi to establish a connection with 
  both a Wi-Fi network and an MQTT broker. It constantly monitors the status of 
  four buttons that are connected to digital inputs. Whenever a button is pressed, 
  it sends a message to a specific MQTT topic. Additionally, the code incorporates 
  functions for displaying Wi-Fi network information and managing received MQTT 
  messages.

  Board: Arduino Uno R4 WiFi
  Component: Button
  Library: https://github.com/arduino-libraries/ArduinoMqttClient (ArduinoMqttClient by Arduino)
*/

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;    // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;  // the WiFi radio's status

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "broker.hivemq.com";
int port = 1883;
const char topic[] = "SunFounder MQTT Test";

//init buttons & states
const int buttonPins[4] = { 2, 3, 4, 5 };
bool previousButtonStates[4] = { false, false, false, false };

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);

  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 5 seconds for connection:
    delay(5000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

  // You can provide a unique client ID, if not set the library uses Arduino-millis()
  // Each client must have a unique client ID
  // mqttClient.setId("clientId");

  // You can provide a username and password for authentication
  // mqttClient.setUsernamePassword("username", "password");

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1)
      ;
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  // set the message receive callback
  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(topic);
  Serial.println();

  // subscribe to a topic
  mqttClient.subscribe(topic);

  // topics can be unsubscribed using:
  // mqttClient.unsubscribe(topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(topic);
  Serial.println();

  // set button pins as INPUT_PULLUP
  for (int i = 0; i < 4; i++) {
    pinMode(buttonPins[i], INPUT_PULLUP);
    previousButtonStates[i] = digitalRead(buttonPins[i]);
  }
}

void loop() {

  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // Check button status
  for (int i = 0; i < 4; i++) {
    bool currentButtonState = digitalRead(buttonPins[i]);

    // If the button is pressed and its previous state was not pressed.
    if (!currentButtonState && previousButtonStates[i]) {
      sendButtonMessage(i + 1);  // The message that the send button has been pressed.
    }

    previousButtonStates[i] = currentButtonState;  // Update button status
  }

  // Add a delay to avoid constant pinging
  delay(50);
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");

  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}


void onMqttMessage(int messageSize) {
  // we received a message, print out the topic and contents
  Serial.print("Received a message with topic '");
  Serial.print(mqttClient.messageTopic());
  Serial.println("'");
  Serial.print("Message length: ");
  Serial.print(messageSize);
  Serial.println(" bytes:");

  // Read the message contents into a String
  String message = mqttClient.readString();

  // Convert the received message and comparison strings to lowercase
  message.toLowerCase();

  Serial.print("Message to me: ");
  Serial.println(message);

  Serial.println();
}

void sendButtonMessage(int buttonNumber) {
  String message = "Button " + String(buttonNumber) + " was pressed.";

  Serial.println(message);

  mqttClient.beginMessage(topic);
  mqttClient.print(message);
  mqttClient.endMessage();
}

コードを実行した後、 HiveMQ Web Client に戻り、ブレッドボード上のボタンのいずれかを押すと、HiveMQ上でメッセージプロンプトが表示されます。

どのように動作するのか？

このコードは、Wi-Fiに接続し、MQTTプロトコルを使用してMQTTブローカーと通信するArduinoベースのプロジェクト用です。さらに、4つのボタンが押されたかどうかを検出し、対応するメッセージをMQTTブローカーに送信することができます。

コードの詳細な説明は以下の通りです：

関連するライブラリを含む：

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>

機密情報を含む：
- arduino_secrets.h ファイルにはWi-FiネットワークのSSIDとパスワードが含まれています。
```
#include "arduino_secrets.h"
char ssid[] = SECRET_SSID;
char pass[] = SECRET_PASS;
```
変数の初期化：
- Wi-FiおよびMQTT接続を管理するための変数。
- ボタンピンとボタンの状態を初期化します。
setup()：
- シリアル通信を初期化します。
- Wi-Fiモジュールの存在をチェックし、Wi-Fiに接続を試みます。
- ネットワークデータを印刷します。
- MQTTブローカーへの接続を試みます。
- MQTTトピックにサブスクライブします。
- ボタンを入力モードに設定します。
loop()：
- MQTT接続をアクティブに保ちます。
- 各ボタンが押されたかどうかをチェックし、もしそうならMQTTメッセージを送信します。
その他のユーティリティ関数：
- printWifiData()：現在接続されているWi-Fiネットワークに関する情報を印刷します。
- printCurrentNet()：現在のネットワークに関する関連データを印刷します。
- printMacAddress(byte mac[])：MACアドレスを印刷します。
- onMqttMessage(int messageSize)：MQTTブローカーからメッセージを受信したときにトリガーされるコールバック関数です。受信したメッセージのトピックと内容を印刷します。
- sendButtonMessage(int buttonNumber)：ボタンが押されたときにMQTTメッセージを送信するためにこの関数を使用します。