注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

• エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。

• 学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。

• 独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。

• 特別割引：最新製品の独占割引をお楽しみください。

• 祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

Bluetooth環境モニター

このプロジェクトでは、MITアップインベンターで作成されたAndroidアプリを使用して、Arduinoボードからの環境データを受信し表示します。ArduinoボードはDHT11センサーから温度と湿度のデータを取得します。データが収集されると、Bluetoothを介して送信されます。アプリはデータを受信すると、画面上に表示します。

Androidアプリケーションは、 MIT App Inventor という無料のWebベースプラットフォームを利用して構築されます。このプロジェクトは、Arduinoとスマートフォンのインターフェースに慣れる絶好の機会を提供します。

必要なコンポーネント

このプロジェクトでは、以下のコンポーネントが必要です。

全てのキットを一括購入するのが便利です。こちらがリンクです:

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

また、以下のリンクから個別に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ブレッドボード	購入
ジャンパーワイヤー	購入
湿温度センサーモジュール	購入

1. 回路を組む

2. Androidアプリを作成する

Androidアプリケーションは、 MIT App Inventor という無料のウェブアプリケーションを使用して開発されます。 MITアップインベンターは、直感的なドラッグアンドドロップ機能により、簡易なアプリケーションを作成するための優れたスタートポイントとして機能します。

さあ、始めましょう。

1. ～の始め方 MIT App Inventor にアクセスし、「オンラインツール」をクリックしてログインします。MITアップインベンターに登録するためにはGoogleアカウントが必要です。

   

2. ログインしたら、 Projects -> Import project (.aia) from my computer に進みます。その後、 elite-explorer-kit-main\iot_project\08-bluetooth_environmental_monitor のパスにある ble_environmental_monitor.aia ファイルをアップロードします。

   また、こちらから直接ダウンロードもできます: ble_environmental_monitor.aia

   

3. .aia ファイルをアップロードすると、MITアップインベンターソフトウェア上にアプリケーションが表示されます。これは事前に設定されたテンプレートです。MITアップインベンターに慣れた後、このテンプレートを変更することができます。

4. MITアップインベンターには、主に Designer と Blocks の2つのセクションがあります。ページの右上隅でこれらのセクション間を切り替えることができます。

   

5. Designer では、ボタン、テキスト、スクリーンを追加したり、アプリケーションの全体的な見た目を変更したりすることができます。

   

6. 次に、 Blocks セクションがあります。このセクションでは、アプリのGUI上の各コンポーネントにカスタム機能を作成し、望ましい機能を実現することができます。

   

7. スマートフォンにアプリケーションをインストールするには、 Build タブに移動します。

   

   • .apk ファイルを生成できます。このオプションを選択すると、 .apk ファイルをダウンロードするか、QRコードをスキャンしてインストールするかを選択するページが表示されます。インストールガイドに従ってアプリケーションのインストールを完了してください。

     こちらから事前にコンパイルされたAPKもダウンロードできます: ble_environmental_monitor.apk

   • このアプリをGoogle Playや他のアプリマーケットにアップロードしたい場合は、 .aab ファイルを生成できます。

3. コードをアップロードする

1. elite-explorer-kit-main\iot_project\08-bluetooth_environmental_monitor のパスにある 08-bluetooth_environmental_monitor.ino ファイルを開くか、このコードを Arduino IDE にコピーします。

   注釈

   ライブラリをインストールするには、Arduinoライブラリマネージャーを使用して、 「DHT sensor library」 と 「ArduinoBLE」 を検索し、インストールします。

08-bluetooth_environmental_monitor.ino

/*
  This code is designed for an Arduino Uno R4 board to read temperature and humidity data 
  from a DHT11 sensor. It then transmits this data via Bluetooth Low Energy (BLE) to a connected 
  device. The code uses the DHT library for reading sensor data and the ArduinoBLE library for 
  Bluetooth communication. The BLE service and characteristics are set up according to the 
  specifications of the Bluetooth SIG for environmental sensing. Additionally, the code includes 
  functions for managing BLE connection and disconnection events, as well as a debug function 
  that prints sensor data to the serial monitor.

  Board: Arduino Uno R4 
  Component: DHT11
  Library: https://github.com/adafruit/DHT-sensor-library  (DHT sensor library by Adafruit)
           https://www.arduino.cc/reference/en/libraries/arduinoble/ (ArduinoBLE by Arduino)
*/


#include <DHT.h>
#include <ArduinoBLE.h>

#define DHTPIN 11      // Define the pin used to connect the sensor
#define DHTTYPE DHT11  // Define the sensor type

// Define UUIDs for BLE Environmental Sensing Service and Characteristics as per Bluetooth SIG specifications
// https://bitbucket.org/bluetooth-SIG/public/src/8a7ea26ae56d43e6fea88693232a01a78e28213e/assigned_numbers/uuids/service_uuids.yaml#lines-104:105
BLEService environmentalSensingService("181A");
// https://bitbucket.org/bluetooth-SIG/public/src/8a7ea26ae56d43e6fea88693232a01a78e28213e/assigned_numbers/uuids/characteristic_uuids.yaml#lines-299:303
BLEShortCharacteristic temperatureCharacteristic("2A6E", BLERead | BLENotify);
BLEUnsignedShortCharacteristic humidityCharacteristic("2A6F", BLERead | BLENotify);

DHT dht(DHTPIN, DHTTYPE);  // Create a DHT object

unsigned long lastUpdateTime = 0;           // Timestamp of last sensor data update
const unsigned long updateInterval = 5000;  // Sensor data update interval (ms)

void setup() {

  Serial.begin(9600);  // Initialize serial communication at 9600 baud
  dht.begin();         // Initialize DHT sensor

  // Initialize BLE, halt if initialization fails
  if (!BLE.begin()) {
    Serial.println("starting Bluetooth® Low Energy module failed!");
    while (1)
      ;
  }

  setupBle();  // Setup BLE service and characteristics
}

void loop() {

  BLE.poll();  // Poll for BLE events

  // Check if it's time to update sensor data
  if (lastUpdateTime == 0 || millis() - lastUpdateTime > updateInterval) {
    float humidity = dht.readHumidity();        // Read humidity
    float temperature = dht.readTemperature();  // Read temperature

    // Check if any reads failed and exit early (to try again).
    if (isnan(humidity) || isnan(temperature)) {
      Serial.println(F("Failed to read from DHT sensor!"));
      return;
    }

    // Debug: print sensor data to serial monitor
    printDHT(humidity, temperature);

    // Update BLE characteristics with new sensor data
    temperatureCharacteristic.writeValue(round(temperature * 100.0));
    humidityCharacteristic.writeValue(round(humidity * 100.0));

    lastUpdateTime = millis();  // Update timestamp
  }
}

void printDHT(float h, float t) {
  // Print humidity and temperature data to serial monitor
  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.println(F("°C "));
}

void setupBle() {
  // Set advertised local name and service UUID:
  BLE.setLocalName("UNO R4 Home");
  BLE.setAdvertisedService(environmentalSensingService);

  // Add characteristics to the service
  environmentalSensingService.addCharacteristic(temperatureCharacteristic);
  environmentalSensingService.addCharacteristic(humidityCharacteristic);

  // Add service
  BLE.addService(environmentalSensingService);

  // Set initial characteristic values
  temperatureCharacteristic.writeValue(0);
  humidityCharacteristic.writeValue(0);

  // Set BLE event handlers for connection and disconnection
  BLE.setEventHandler(BLEConnected, blePeripheralConnectHandler);
  BLE.setEventHandler(BLEDisconnected, blePeripheralDisconnectHandler);

  // Start advertising
  BLE.advertise();
}

void blePeripheralConnectHandler(BLEDevice central) {
  // Handle BLE peripheral connect event
  digitalWrite(LED_BUILTIN, HIGH);  // Turn on built-in LED
  Serial.print(F("Connected to central: "));
  Serial.println(central.address());
}

void blePeripheralDisconnectHandler(BLEDevice central) {
  // Handle BLE peripheral disconnect event
  digitalWrite(LED_BUILTIN, LOW);  // Turn off built-in LED
  Serial.print(F("Disconnected from central: "));
  Serial.println(central.address());
}

1. 正しいボードとポートを選択したら、 Upload ボタンをクリックします。

2. シリアルモニター（ボーレートは 9600 に設定）を開き、デバッグメッセージを確認します。

4. アプリとBluetoothモジュールの接続

先に作成したアプリケーションがスマートフォンにインストールされていることを確認します。

1. まず、スマートフォンで Bluetooth をオンにします。

   

2. 次に、新しくインストールされた Environmental Monitor アプリを開きます。

   

3. このアプリを初めて開くと、Bluetoothの使用に必要な許可を求める2つのプロンプトが連続して表示されます。

   
   

4. アプリ内で Connect ボタンをクリックし、アプリとBluetoothモジュール間の接続を確立します。

   

5. このページには、すべてのペアリングされたBluetoothデバイスのリストが表示されます。リストから xx.xx.xx.xx.xx.xx UNO R4 Home オプションを選択します。各デバイスの名前はMACアドレスの隣にリストされています。

   
   

6. 上記のページにデバイスが表示されない場合は、デバイスの位置情報スイッチをオンにしてみてください（一部のAndroidシステムバージョンでは、Bluetooth機能と位置情報スイッチが統合されています）。

   
   

7. 接続が成功すると、メインページにリダイレクトされ、そこで温度と湿度が表示されます。

   

5. コードの説明

1. ライブラリのインポートと定数の定義

   • 必要なライブラリをインポートし、DHTセンサーピンとタイプに関する定数を定義します。

   注釈

   ライブラリをインストールするには、Arduinoライブラリマネージャーを使用して、 「DHT sensor library」 と 「ArduinoBLE」 を検索し、インストールします。

   #include <DHT.h>
   #include <ArduinoBLE.h>
   #define DHTPIN 11
   #define DHTTYPE DHT11
   

2. BLEサービスと特性の初期化

   • BLE環境センシングサービスと特性のUUIDを定義します。 ブルートゥース SIG によって提供された事前定義されたUUIDを使用しています。 環境センシングサービス には 0x181A が割り当てられ、それぞれ 0x2A6E と 0x2A6F は 温度と湿度 用に予約されています。

   BLEService environmentalSensingService("181A");
   BLEShortCharacteristic temperatureCharacteristic("2A6E", BLERead | BLENotify);
   BLEUnsignedShortCharacteristic humidityCharacteristic("2A6F", BLERead | BLENotify);
   

3. Setup関数

   • シリアル通信、DHTセンサー、BLEを初期化します。

   void setup() {
     Serial.begin(9600);
     dht.begin();
     if (!BLE.begin()) {
       Serial.println("starting Bluetooth® Low Energy module failed!");
       while (1)
         ;
     }
     setupBle();
   }
   

4. メインループ

   • BLEイベントをポーリングし、定期的にセンサーデータを更新します。

   • millis() - lastUpdateTime > updateInterval の行は、センサーデータがupdateIntervalミリ秒ごとに更新されることを保証します。

   void loop() {
     BLE.poll();
     if (millis() - lastUpdateTime > updateInterval) {
       // Read sensor data and update BLE characteristics
     }
   }
   

5. BLEおよびデバッグ関数

   BLEを設定し、デバッグ情報を出力し、BLEイベントを管理するための関数。

   void printDHT(float h, float t) { /* ... */ }
   void setupBle() { /* ... */ }
   void blePeripheralConnectHandler(BLEDevice central) { /* ... */ }
   void blePeripheralDisconnectHandler(BLEDevice central) { /* ... */ }
   

   • printDHT(float h, float t): DHT11によって読み取られた温度と湿度のデータをシリアルモニターに出力するために使用されます。この関数はデバッグ目的のためです。

   • setupBle(): ブロードキャスト名、特性、およびサービスを設定を含むBluetoothを初期化します。

   • blePeripheralConnectHandler(BLEDevice central) および blePeripheralDisconnectHandler(BLEDevice central): これらの関数は、Bluetoothが接続または切断されたときのイベントを処理します。デバイスがUNO R4とBluetooth経由で正常に接続すると、オンボードLEDが点灯します。デバイスが切断されると、LEDが消灯します。