注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

• エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。

• 学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。

• 独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。

• 特別割引：最新製品の独占割引をお楽しみください。

• 祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

CheerLights

CheerLightsは、誰でも制御できるグローバルな同期ライトのネットワークです。 @CheerLights - Twitter のLEDカラーチェンジコミュニティに参加し、世界中のLEDを同時に色を変えられるようにしましょう。オフィスの片隅にLEDを置いて、自分が一人でないことを思い出しましょう。

このケースでは、MQTTを使用しますが、自分のメッセージを公開する代わりに、「cheerlights」というトピックにサブスクライブします。これにより、他の人が「cheerlights」トピックに送信したメッセージを受信し、その情報を使用してLEDストリップの色を変更することができます。

必要なコンポーネント

このプロジェクトには以下のコンポーネントが必要です。

全体のキットを購入すると便利です。こちらがリンクです：

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

以下のリンクから別々に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ジャンパーワイヤー	購入
WS2812 RGB 8 LEDストリップ	購入

配線図

回路図

ライブラリのインストール

ライブラリをインストールするには、Arduinoライブラリマネージャーを使用し、「ArduinoMqttClient」と「FastLED」を検索してインストールしてください。

ArduinoMqttClient.h：MQTT通信用に使用します。

FastLED.h：RGB LEDストリップのドライブに使用します。

コードの実行

注釈

• ファイル 05_cheerlight.ino を elite-explorer-kit-main\iot_project\05_cheerlight のパスから直接開くことができます。

• または、このコードをArduino IDEにコピーしてください。

注釈

コード内で、SSIDとパスワードは arduino_secrets.h に格納されています。この例をアップロードする前に、自分のWiFiの認証情報でそれらを修正する必要があります。さらに、コードを共有または保存する際には、この情報を機密に保つためのセキュリティ対策を講じてください。

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)

05_cheerlight.ino

/*
  The code is designed for an Arduino Uno R4 WiFi to connect to a Wi-Fi network, 
  subscribe to an MQTT topic, and control a chain of NeoPixel LEDs based on messages 
  received from the MQTT broker. It listens for color commands from the cheerlights 
  topic and updates the LED colors accordingly.

  Board: Arduino Uno R4 WiFi
  Component: WS2812
  Library: https://github.com/arduino-libraries/ArduinoMqttClient (ArduinoMqttClient by Arduino)
           https://github.com/FastLED/FastLED (FastLED by Daniel Garcia)
           
*/

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>
#include <FastLED.h>

#define NUM_LEDS 8  // Number of LEDs in the chain
#define DATA_PIN 6  // Data pin for LED control

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;    // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;  // the WiFi radio's status

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "mqtt.cheerlights.com";
int port = 1883;
const char topic[] = "cheerlights";



CRGB leds[NUM_LEDS];  // Array to hold LED color data

// Define the supported CheerLights colors and their RGB values
String colorName[] = { "red", "pink", "green", "blue", "cyan", "white", "warmwhite", "oldlace", "purple", "magenta", "yellow", "orange" };

int colorRGB[][3] = { 255, 0, 0,      // "red"
                      255, 192, 203,  // "pink"
                      0, 255, 0,      // "green"
                      0, 0, 255,      // "blue"
                      0, 255, 255,    // "cyan"
                      255, 255, 255,  // "white"
                      255, 223, 223,  // "warmwhite"
                      255, 223, 223,  // "oldlace"
                      128, 0, 128,    // "purple"
                      255, 0, 255,    // "magenta"
                      255, 255, 0,    // "yellow"
                      255, 165, 0 };  // "orange"


void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);

  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

  // You can provide a unique client ID, if not set the library uses Arduino-millis()
  // Each client must have a unique client ID
  // mqttClient.setId("clientId");

  // You can provide a username and password for authentication
  // mqttClient.setUsernamePassword("username", "password");

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1)
      ;
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  // set the message receive callback
  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(topic);
  Serial.println();

  // subscribe to a topic
  mqttClient.subscribe(topic);

  // topics can be unsubscribed using:
  // mqttClient.unsubscribe(topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(topic);
  Serial.println();

  FastLED.addLeds<NEOPIXEL, DATA_PIN>(leds, NUM_LEDS);  // Initialize LEDs
}

void loop() {

  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // Add a delay to avoid constant pinging
  delay(5000);
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");

  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}


void onMqttMessage(int messageSize) {
  // we received a message, print out the topic and contents
  Serial.print("Received a message with topic '");
  Serial.print(mqttClient.messageTopic());
  Serial.println("'");
  Serial.print("Message length: ");
  Serial.print(messageSize);
  Serial.println(" bytes:");

  // Read the message contents into a String
  String message = mqttClient.readString();

  // Convert the received message and comparison strings to lowercase
  message.toLowerCase();

  // If a message is received on the topic, you will check this message.
  // Changes the output state according to the message
  if (String(topic) == "cheerlights") {
    Serial.print("Changing color to ");
    Serial.println(message);
    setColor(message);
  }
}

void setColor(String color) {
  // Loop through the list of colors to find the matching color
  for (int colorIndex = 0; colorIndex < 12; colorIndex++) {
    if (color == colorName[colorIndex]) {
      // Set the color of each NeoPixel on the strip
      for (int pixel = 0; pixel < NUM_LEDS; pixel++) {
        leds[pixel] = CRGB(colorRGB[colorIndex][0], colorRGB[colorIndex][1], colorRGB[colorIndex][2]);
      }
      FastLED.show();
    }
  }
}

グローバルな@CheerLightsデバイスを制御する

1. Discordサーバー に参加し、 /CheerLights ボットを利用して色を設定します。 CheerLights Discord Server の任意のチャンネルで「/cheerlights」と入力してボットをアクティブにします。

   

2. ボットが提供する指示に従って色を設定します。これにより、グローバルにCheerLightsデバイスを制御できます。

   

どのように動作するのか？

こちらはコードの主要部分とその機能の説明です：

1. 必要なライブラリを含む：

   • WiFiS3.h：Wi-Fi接続の処理に使用します。

   • ArduinoMqttClient.h：MQTT接続の処理に使用します。

   • FastLED.h：NeoPixel LEDストリップの制御に使用します。

2. いくつかの定数を定義する：

   • NUM_LEDS：LEDストリップ上のLEDの数。

   • DATA_PIN：LEDストリップを制御するためにArduinoに接続されているデータピン。

   • arduino_secrets.h：Wi-Fiネットワーク名とパスワードを含むヘッダーファイルで、機密情報を保護します。

   • broker：MQTTサーバーのアドレス。

   • port：MQTTサーバーのポート。

   • topic：サブスクライブするMQTTトピック。

3. いくつかのグローバル変数を定義する：

   • CRGB leds[NUM_LEDS]：LEDの色データを格納するための配列。

   • colorName：CheerLightsプロジェクトでサポートされている色名の配列。

   • colorRGB：色名に対応するRGBカラーコードの配列。

4. setup() 関数：

   • シリアル通信を初期化します。

   • Wi-Fiモジュールが存在するかを確認し、そのファームウェアバージョンを出力します。

   • Wi-Fiネットワークに接続を試み、失敗した場合は10秒待って再試行します。

   • 接続に成功したら、MQTTブローカー（サーバー）に接続し、指定されたトピックにサブスクライブします。

   • NeoPixel LEDストリップを初期化します。

5. loop() 関数：

   • 定期的に mqttClient.poll() 関数を呼び出して、MQTTメッセージを受信し、MQTTのキープアライブ信号を送信します。

   • 継続的な接続を避けるために5秒の遅延を追加します。

6. printWifiData() および printCurrentNet() 関数は、Wi-Fiネットワークおよび接続情報を出力するために使用されます。

7. printMacAddress() 関数は、MACアドレスを16進数形式で印刷するために使用されます。

8. onMqttMessage() 関数は、MQTTメッセージが受信されたときにトリガーされるコールバック関数です。受信したトピックとメッセージ内容を出力し、メッセージ内容を小文字に変換します。トピックが「cheerlights」の場合、 setColor() 関数を呼び出して、LEDストリップの色を設定します。

9. setColor() 関数は、色名をパラメータとして取り、 colorName 配列で一致する色を探します。一致する色が見つかった場合、LEDストリップの色を対応するRGB値に設定し、 FastLED.show() 関数を使用してLEDストリップの色を更新します。