注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

• エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。

• 学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。

• 独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。

• 特別割引：最新製品の独占割引をお楽しみください。

• 祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

IFTTTを使用したセキュリティシステム

このプロジェクトでは、PIRセンサーを使用して侵入者や家に入ってくる野良動物を検出するセキュリティデバイスを作成します。侵入が発生した場合、メールアラートを受け取ります。

基本的なサービスとしてWebhooksを利用します。UNO R4からIFTTTのサービスへPOSTリクエストが送信されます。

必要なコンポーネント

このプロジェクトには以下のコンポーネントが必要です。

全体のキットを購入すると便利です。こちらがリンクです：

名称	このキットのアイテム数	リンク
Elite Explorer Kit	300+	Elite Explorer Kit

以下のリンクから別々に購入することもできます。

コンポーネント紹介	購入リンク
Arduino Uno R4 WiFi	-
ジャンパーワイヤー	購入
PIR動作センサーモジュール	購入

配線図

回路図

IFTTTの設定

IFTTTは、さまざまなデータサービスを連携する方法を提供する無料のサービスです。

ウェブフック（カスタムURL）をIFTTTに送信して応答するAppletを作成し、その後メールを送信します。

IFTTTで以下の手順に従ってください。

1. IFTTT にアクセスしてログインまたはアカウントを作成します。

   

2. Create をクリックします。

   

3. If This イベントを追加します。

   

4. Webhooks を検索します。

   

5. Receive a web request を選択します。

   

6. イベント名（例：SecurityWarning）を入力し、 Create trigger をクリックします。

   

7. Then That イベントを追加します。

   

8. Emailを検索します。

   

9. Send me an email を選択します。

   

10. Subject と Body を入力し、 Create action をクリックします。

11. Continue をクリックして設定を完了します。

12. 必要に応じてタイトル名を調整します。

13. Appletの詳細ページに自動的にリダイレクトされます。ここで、Appletが現在接続されていることが確認でき、スイッチを切り替えて有効/無効にすることができます。

14. IFTTT Appletを作成したので、デバイスがIFTTTにアクセスするために必要なWebhooksキーも必要です。これは、 Webhooks 設定 から取得できます。

15. Webhooksキーを「arduino_secrets.h」にコピーし、SSIDとパスワードを入力してください。

    #define SECRET_SSID "your_ssid"        // your network SSID (name)
    #define SECRET_PASS "your_password"        // your network password (used for WPA, or as a key for WEP)
    #define WEBHOOKS_KEY "your_key"
    

コードの実行

注釈

• ファイル 03_ifttt_pir.ino を elite-explorer-kit-main\iot_project\03_ifttt_pir のパスから直接開くことができます。

• または、このコードをArduino IDEにコピーしてください。

注釈

コード内で、SSIDとパスワードは arduino_secrets.h に格納されています。この例をアップロードする前に、自分のWiFiの認証情報でそれらを修正する必要があります。さらに、コードを共有または保存する際には、この情報を機密に保つためのセキュリティ対策を講じてください。

警告

メールボックスが溢れるのを防ぐため、このプロジェクトのコードを実行する前に PIR動作センサーモジュール をデバッグしてください。

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)
#define WEBHOOKS_KEY "your_key"

03_ifttt_pir.ino

/*
  This code is designed to connect an Arduino Uno R4 WiFi board to the internet and detect 
  motion using a PIR sensor. Upon detecting motion, it sends an HTTP GET request 
  to the IFTTT web service to trigger an event named "SecurityWarning". The code handles 
  WiFi connection setup, motion detection, server communication, and provides feedback via 
  the serial monitor.

  Board: Arduino Uno R4 WiFi
  Component: PIR Motion Sensor Module
*/

#include "WiFiS3.h"           // Include the WiFiS3 library for internet connectivity
#include "arduino_secrets.h"  // Include the file containing Wi-Fi credentials

// Wi-Fi credentials are stored in arduino_secrets.h
char ssid[] = SECRET_SSID;
char pass[] = SECRET_PASS;

int status = WL_IDLE_STATUS;
WiFiClient client;

// IFTTT server information and event name
char server[] = "maker.ifttt.com";
char event[] = "SecurityWarning";
String webRequestURL = "/trigger/" + String(event) + "/with/key/" + String(WEBHOOKS_KEY);

const int pirPin = 2;         // PIR sensor is connected to digital pin 2
bool motionDetected = false;  // Variable to track motion detection

void setup() {
  Serial.begin(9600);
  while (!Serial) {
    ;
  }

  // Check the status of the WiFi module
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    while (1)
      ;  // Infinite loop to halt further execution
  }

  // Check if the WiFi firmware is up to date
  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // Attempt to connect to the Wi-Fi network
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    status = WiFi.begin(ssid, pass);
  }
  printWifiStatus();  // Print the status of the WiFi connection

  pinMode(pirPin, INPUT);
}

void loop() {
  readResponse();  // Read and print server response if available

  // Check for motion using PIR sensor
  if (digitalRead(pirPin) == HIGH) {
    if (!motionDetected) {
      Serial.println("Motion detected!");
      triggerIFTTTEvent();  // Trigger IFTTT notification
      motionDetected = true;
    }
  } else {
    motionDetected = false;
  }
}

void readResponse() {
  // Read incoming data from the WiFi connection
  uint32_t received_data_num = 0;
  while (client.available()) {
    char c = client.read();
    Serial.print(c);
    received_data_num++;
    if (received_data_num % 80 == 0) {
      Serial.println();
    }
  }
}

void triggerIFTTTEvent() {
  client.stop();  // Terminate any existing connections

  // Attempt to connect to the IFTTT server
  if (client.connect(server, 80)) {  // If the connection is successful
    Serial.println("connecting...");
    // Construct and send the HTTP GET request
    client.println("GET " + webRequestURL + " HTTP/1.1");
    client.println("Host: maker.ifttt.com");
    client.println("User-Agent: ArduinoWiFi/1.1");
    client.println("Connection: close");
    client.println();  // End of HTTP request
  } else {
    Serial.println("connection failed");  // Notify if the connection fails
  }
}

void printWifiStatus() {
  // Print the current Wi-Fi status to the serial monitor
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  long rssi = WiFi.RSSI();
  Serial.print("Signal Strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}

どのように動作するのか？

1. 必要なライブラリとヘッダーファイルを含みます：

   • 「WiFiS3.h」: Wi-Fi接続の管理に使用します。

   • 「arduino_secrets.h」: Wi-Fiネットワーク名とパスワードなどの機密情報を含みます。

2. グローバル変数と定数を定義します：

   • ssid: Wi-Fiネットワークの名前。

   • pass: Wi-Fiネットワークのパスワード。

   • status: Wi-Fi接続の状態。

   • client: Wi-Fiサーバーとの通信に使用するクライアント。

   • server: IFTTT Webhookサーバーのアドレス。

   • event: IFTTT Webhookイベントの名前。

   • webRequestURL: HTTPリクエストを送信するための構築されたURL。Webhookイベント名とキーを含みます。

   • pirPin: PIRセンサーが接続されているデジタルピン。

   • motionDetected: 動き検出を追跡するフラグ変数。

3. setup() 関数：

   • シリアル通信を初期化します。

   • Wi-Fiモジュールの存在をチェックし、そのファームウェアバージョンを出力します。

   • Wi-Fiネットワークに接続を試み、失敗した場合は再試行します。

   • PIRセンサーが接続されているピンを入力モードに設定します。

4. readResponse() 関数：

   • IFTTTサーバーからのHTTP応答データを読み取り、シリアルコンソールに印刷します。

5. loop() 関数：

   • readResponse() 関数を呼び出してHTTP応答データを読み取ります。

   • PIRセンサーを使用して動きをチェックします。動きが検出され、以前に検出されていない場合：

     • コンソールに「動きを検出！」と印刷します。

     • triggerIFTTTEvent() 関数を呼び出し、IFTTTサーバーにHTTPリクエストを送信し、Webhookイベントをトリガーします。

     • motionDetected フラグを true に設定して、動きが検出されたことを示します。

   • 動きが検出されない場合は、 motionDetected フラグを false に設定します。

6. triggerIFTTTEvent() 関数：

   • IFTTTサーバーとの接続を確立します。

   • HTTP GETリクエストを送信し、WebhookイベントのURLと他のHTTPヘッダーを含みます。

7. printWifiStatus() 関数：

   • 接続されているWi-Fiネットワークに関する情報をシリアルコンソールに出力します。これにはSSID、IPアドレス、信号強度（RSSI）が含まれます。