Note

Hello, welcome to the SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts Community on Facebook! Dive deeper into Raspberry Pi, Arduino, and ESP32 with fellow enthusiasts.

Why Join?

Expert Support: Solve post-sale issues and technical challenges with help from our community and team.
Learn & Share: Exchange tips and tutorials to enhance your skills.
Exclusive Previews: Get early access to new product announcements and sneak peeks.
Special Discounts: Enjoy exclusive discounts on our newest products.
Festive Promotions and Giveaways: Take part in giveaways and holiday promotions.

👉 Ready to explore and create with us? Click [here] and join today!

WeatherTime Screen

This sketch connects to a WiFi network, fetches weather data from OpenWeatherMap every minute, retrieves the current time from an NTP server, and displays the day, time, and weather information on an OLED screen.

Required Components

In this project, we need the following components.

It’s definitely convenient to buy a whole kit, here’s the link:

Name	ITEMS IN THIS KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

You can also buy them separately from the links below.

COMPONENT INTRODUCTION	PURCHASE LINK
Arduino Uno R4 WiFi	-
Jumper Wires	BUY
OLED Display Module	BUY

Wiring

Schematic

OpenWeather

Get OpenWeather API keys

OpenWeather is an online service, owned by OpenWeather Ltd, that provides global weather data via API, including current weather data, forecasts, nowcasts and historical weather data for any geographical location.

Visit OpenWeather to log in/create an account.
Click into the API page from the navigation bar.
Find Current Weather Data and click Subscribe.
Under Current weather and forecasts collection, subscribe to the appropriate service. In our project, Free is good enough.
Copy the Key from the API keys page.

Copy it to the arduino_secrets.h.

#define SECRET_SSID "<SSID>"        // your network SSID (name)
#define SECRET_PASS "<PASSWORD>"        // your network password
#define API_KEY "<OpenWeather_API_KEY>"
#define LOCATION "<YOUR CITY>"

Set the time zone of your location.

Take the capital of Sweden, Stockholm, as an example. Search “stockholm timezone” on Google.

In the search results, you will see “GMT+1”, so you set the parameter of the function below to 3600 * 1 seconds.
```
timeClient.setTimeOffset(3600 * 1);  // Adjust for your time zone (this is +1 hour)
```

Install the Library

To install the library, use the Arduino Library Manager and search for “ArduinoMqttClient”, “FastLED”, “Adafruit GFX” and “Adafruit SSD1306” and install them.

ArduinoJson.h: Used for handling JSON data (data obtained from openweathermap).

NTPClient.h: Used for obtaining real-time time.

Adafruit_GFX.h, Adafruit_SSD1306.h: Used for OLED module.

Run the Code

Note

You can open the file 06_weather_oled.ino under the path of elite-explorer-kit-main\iot_project\06_weather_oled directly.
Or copy this code into Arduino IDE.

Note

In the code, SSID and password are stored in arduino_secrets.h. Before uploading this example, you need to modify them with your own WiFi credentials.

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)
#define API_KEY "your_key"
#define LOCATION "your_location"

06_weather_oled.ino

/*
  The code fetches and shows weather information such as temperature, humidity, pressure, 
  and wind details. This information is obtained from the OpenWeatherMap API through a WiFi 
  connection. The program initially connects to the WiFi network and retrieves the current 
  time from an NTP server. It then regularly sends HTTP requests to retrieve weather data 
  from the OpenWeatherMap API. Upon receiving a JSON response, it parses the data and displays 
  both the weather information and current time on the OLED screen.

  Board: Arduino Uno R4 WiFi
  Component: OLED
  Library: https://github.com/bblanchon/ArduinoJson (ArduinoJson by Benoit Blanchon)
           https://github.com/adafruit/Adafruit_SSD1306 (Adafruit SSD1306 by Adafruit)  
           https://github.com/adafruit/Adafruit-GFX-Library (Adafruit GFX Library by Adafruit) 
           https://github.com/arduino-libraries/NTPClient (NTPClient by Fabrice Weinberg) 
           
*/

#include "WiFiS3.h"
#include <ArduinoJson.h>  // JSON decoding library
#include "arduino_secrets.h"

// NTP client setup to get real-time data
#include <NTPClient.h>
#include <WiFiUdp.h>
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "pool.ntp.org");  // NTP server

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define SCREEN_WIDTH 128  // OLED display width, in pixels
#define SCREEN_HEIGHT 64  // OLED display height, in pixels
#define OLED_RESET 4      // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// WiFi credentials and server information
char ssid[] = SECRET_SSID;  // your network SSID (name)
char pass[] = SECRET_PASS;  // your network password
int status = WL_IDLE_STATUS;
char server[] = "api.openweathermap.org";  // name address for OWM (using DNS)

// Timing variables to manage update intervals
unsigned long lastConnectionTime = 0;               // last time you connected to the server, in milliseconds
const unsigned long postingInterval = 60L * 1000L;  // delay between updates, in milliseconds

// WiFi client for connecting to the API server
WiFiClient client;

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    status = WiFi.begin(ssid, pass);
    delay(5000);  // Wait 5 seconds before retrying
  }

  printWifiStatus();

  // Initialize and clear OLED display
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.display();
  display.clearDisplay();

  // Initialize and clear OLED display
  timeClient.begin();
  timeClient.setTimeOffset(3600 * 8);  // Adjust for your time zone (this is +8 hour)
}

void loop() {

  read_response();
  timeClient.update();

  // Check if it's time to send a new request
  if (!lastConnectionTime || millis() - lastConnectionTime > postingInterval) {
    httpRequest();
  }
}


void read_response() {
  uint32_t received_data_num = 0;
  String payload = "";
  bool jsonDetected = false;

  // Read data from the client connection
  while (client.available()) {
    /* actual data reception */
    char c = client.read();
    
    // for debug
    Serial.print(c);
    
    if ('{' == c) {
      jsonDetected = true;
    }
    if (jsonDetected) {
      payload += c;
    }
    received_data_num++;
  }
  if (jsonDetected) {
    /* print data to serial port */
    // Serial.print("data num : ");
    // Serial.println(received_data_num);
    // Serial.print("data : ");
    // Serial.println(payload);
    DynamicJsonDocument root(1024);
    DeserializationError error = deserializeJson(root, payload);
    if (error) {
      Serial.print("Deserialization failed with code: ");
      Serial.println(error.c_str());
      return;
    }

    String weather = (root["weather"][0]["main"]);
    float temp = (float)(root["main"]["temp"]) - 273.15;        // get temperature in °C
    int humidity = root["main"]["humidity"];                    // get humidity in %
    float pressure = (float)(root["main"]["pressure"]) / 1000;  // get pressure in bar
    float wind_speed = root["wind"]["speed"];                   // get wind speed in m/s
    int wind_degree = root["wind"]["deg"];                      // get wind degree in °

    // // print data
    // Serial.println("Temperature= " + String(temp) + " °C");
    // Serial.println("Humidity = " + String(humidity) + " %");
    // Serial.println("Pressure = " + String(pressure) + " bar");
    // Serial.println("Wind speed = " + String(wind_speed) + " m/s");
    // Serial.println("Wind degree = " + String(wind_degree) + " °");
    displayWeatherData(weather, temp, humidity, pressure, wind_speed);
  }
}


void httpRequest() {
  // close any connection before send a new request.
  client.stop();

  // Construct HTTP GET request for OpenWeatherMap API
  String httpRequest = "";
  httpRequest += "GET /data/2.5/weather?q=" LOCATION "&APPID=" API_KEY " HTTP/1.1";

  // if you get a connection, report back via serial:
  if (client.connect(server, 80)) {
    Serial.println("connected");
    // Make a HTTP request:
    client.println(httpRequest);
    client.println("Host: api.openweathermap.org");
    client.println("Connection: close");
    client.println();
    // note the time that the connection was made:
    lastConnectionTime = millis();
  } else {
    // if you couldn't make a connection:
    Serial.println("connection failed");
  }
}

void printWifiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}

void displayWeatherData(String weather, float temp, int humidity, float pressure, float wind_speed) {
  display.clearDisplay();
  display.setTextSize(1);               // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE);  // Draw white text
  display.setCursor(0, 0);              // Start at top-left corner

  // Display Day of the Week
  String daysOfTheWeek[7] = { "Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday" };
  display.print(daysOfTheWeek[timeClient.getDay()]);

  display.print(" ");
  if (timeClient.getHours() < 10) display.print("0");  // Add leading zero for hours < 10
  display.print(timeClient.getHours());
  display.print(":");
  if (timeClient.getMinutes() < 10) display.print("0");  // Add leading zero for minutes < 10
  display.println(timeClient.getMinutes());

  display.println();
  display.print(LOCATION);
  display.println(" " + weather);

  // Display Weather
  display.print("Temperature: ");
  display.print(temp);
  display.println(" C");

  display.print("Humidity: ");
  display.print(humidity);
  display.println(" %");

  display.print("Pressure: ");
  display.print(pressure);
  display.println(" bar");

  display.print("Wind: ");
  display.print(wind_speed);
  display.println(" m/s");

  display.display();
}

How it works?

Libraries and Definitions:
1. WiFiS3.h: This is likely a library specific to a certain WiFi module or board to manage WiFi connections.
2. ArduinoJson.h: This library is used for decoding (and encoding) JSON data.
3. arduino_secrets.h: A separate file where sensitive data (like WiFi credentials) are stored. This is a good practice to keep credentials out of the main code.
4. NTPClient & WiFiUdp: These are used for fetching the current time from an NTP (Network Time Protocol) server.
5. Adafruit libraries: Used for managing the OLED display.
6. Various global variables: These include WiFi credentials, server details, and more, which will be used throughout the script.
setup():
1. It initializes the serial communication.
2. Checks and prints the WiFi module’s firmware version.
3. Tries to connect to the WiFi network using the provided SSID and password.
4. Prints the connected WiFi’s status (SSID, IP, Signal strength).
5. Initializes the OLED display.
6. Starts the NTP client to fetch the current time and sets a time offset (in this case, 8 hours which might correspond to a specific timezone).
read_response():
1. Reads the response from the server, specifically looking for JSON data (denoted by { and }).
2. If JSON data is found, it decodes the data to extract weather details like temperature, humidity, pressure, wind speed, and wind direction.
3. Calls the displayWeatherData function to display the weather information on the OLED screen.
httpRequest():
1. Closes any existing connections to ensure the WiFi module’s socket is free.
2. Tries to connect to the OpenWeatherMap server.
3. If connected, sends an HTTP GET request to fetch the weather data for a specific location defined by LOCATION (likely defined in arduino_secrets.h or elsewhere).
4. Records the time the request was made.
loop():
1. Calls the read_response function to process any incoming data from the server.
2. Updates the time from the NTP server.
3. Checks if it’s time to make another request to the weather server (based on the postingInterval). If so, it calls the httpRequest function.
printWifiStatus():
1. The SSID of the connected network.
2. The local IP address of the board.
3. The signal strength (RSSI).
displayWeatherData():
1. Clears the OLED screen.
2. Displays the current day of the week.
3. Displays the current time in HH:MM format.
4. Displays the provided weather data (temperature, humidity, pressure, and wind speed).