Note

Hello, welcome to the SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts Community on Facebook! Dive deeper into Raspberry Pi, Arduino, and ESP32 with fellow enthusiasts.

Why Join?

• Expert Support: Solve post-sale issues and technical challenges with help from our community and team.

• Learn & Share: Exchange tips and tutorials to enhance your skills.

• Exclusive Previews: Get early access to new product announcements and sneak peeks.

• Special Discounts: Enjoy exclusive discounts on our newest products.

• Festive Promotions and Giveaways: Take part in giveaways and holiday promotions.

👉 Ready to explore and create with us? Click [here] and join today!

CheerLights

CheerLights is a global network of synchronized lights that can be controlled by anyone. Join the @CheerLights - Twitter LED color-changing community, which allows LEDs around the world to change colors simultaneously. Place your LEDs in a corner of your office to remind yourself that you are not alone.

In this case, we also utilize MQTT, but instead of publishing our own messages, we subscribe to the “cheerlights” topic. This allows us to receive messages sent by others to the “cheerlights” topic and use that information to change the color of our LED strip accordingly.

Required Components

In this project, we need the following components.

It’s definitely convenient to buy a whole kit, here’s the link:

Name	ITEMS IN THIS KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

You can also buy them separately from the links below.

COMPONENT INTRODUCTION	PURCHASE LINK
Arduino Uno R4 WiFi	-
Jumper Wires	BUY
WS2812 RGB 8 LEDs Strip	BUY

Wiring

Schematic

Install the Library

To install the library, use the Arduino Library Manager and search for “ArduinoMqttClient” and “FastLED” and install them.

ArduinoMqttClient.h: Used for MQTT communication.

FastLED.h: Used to drive the RGB LED Strip.

Important

With the release of FastLED 3.7.0, the FastLED library now officially supports the Arduino UNO R4. Therefore, you no longer need to manually install the development version. Simply update or install the FastLED library using the Arduino Library Manager.

Warning

[Outdated] Since the FastLED library has not officially released a version supporting Arduino R4 yet, you’ll need to download the latest development code of the FastLED library and overwrite the existing FastLED library files. For detailed instructions on how to do this, please refer to the Manual Installation section. (This note will be retracted when the FastLED library officially releases an update that supports the Arduino UNO R4.)

Run the Code

Note

• You can open the file 05_cheerlight.ino under the path of elite-explorer-kit-main\iot_project\05_cheerlight directly.

• Or copy this code into Arduino IDE.

Note

In the code, SSID and password are stored in arduino_secrets.h. Before uploading this example, you need to modify them with your own WiFi credentials.

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)

05_cheerlight.ino

/*
  The code is designed for an Arduino Uno R4 WiFi to connect to a Wi-Fi network, 
  subscribe to an MQTT topic, and control a chain of NeoPixel LEDs based on messages 
  received from the MQTT broker. It listens for color commands from the cheerlights 
  topic and updates the LED colors accordingly.

  Board: Arduino Uno R4 WiFi
  Component: WS2812
  Library: https://github.com/arduino-libraries/ArduinoMqttClient (ArduinoMqttClient by Arduino)
           https://github.com/FastLED/FastLED (FastLED by Daniel Garcia)
           
*/

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>
#include <FastLED.h>

#define NUM_LEDS 8  // Number of LEDs in the chain
#define DATA_PIN 6  // Data pin for LED control

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;    // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;  // the WiFi radio's status

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "mqtt.cheerlights.com";
int port = 1883;
const char topic[] = "cheerlights";



CRGB leds[NUM_LEDS];  // Array to hold LED color data

// Define the supported CheerLights colors and their RGB values
String colorName[] = { "red", "pink", "green", "blue", "cyan", "white", "warmwhite", "oldlace", "purple", "magenta", "yellow", "orange" };

int colorRGB[][3] = { 255, 0, 0,      // "red"
                      255, 192, 203,  // "pink"
                      0, 255, 0,      // "green"
                      0, 0, 255,      // "blue"
                      0, 255, 255,    // "cyan"
                      255, 255, 255,  // "white"
                      255, 223, 223,  // "warmwhite"
                      255, 223, 223,  // "oldlace"
                      128, 0, 128,    // "purple"
                      255, 0, 255,    // "magenta"
                      255, 255, 0,    // "yellow"
                      255, 165, 0 };  // "orange"


void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);

  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

  // You can provide a unique client ID, if not set the library uses Arduino-millis()
  // Each client must have a unique client ID
  // mqttClient.setId("clientId");

  // You can provide a username and password for authentication
  // mqttClient.setUsernamePassword("username", "password");

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1)
      ;
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  // set the message receive callback
  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(topic);
  Serial.println();

  // subscribe to a topic
  mqttClient.subscribe(topic);

  // topics can be unsubscribed using:
  // mqttClient.unsubscribe(topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(topic);
  Serial.println();

  FastLED.addLeds<NEOPIXEL, DATA_PIN>(leds, NUM_LEDS);  // Initialize LEDs
}

void loop() {

  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // Add a delay to avoid constant pinging
  delay(5000);
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");

  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}


void onMqttMessage(int messageSize) {
  // we received a message, print out the topic and contents
  Serial.print("Received a message with topic '");
  Serial.print(mqttClient.messageTopic());
  Serial.println("'");
  Serial.print("Message length: ");
  Serial.print(messageSize);
  Serial.println(" bytes:");

  // Read the message contents into a String
  String message = mqttClient.readString();

  // Convert the received message and comparison strings to lowercase
  message.toLowerCase();

  // If a message is received on the topic, you will check this message.
  // Changes the output state according to the message
  if (String(topic) == "cheerlights") {
    Serial.print("Changing color to ");
    Serial.println(message);
    setColor(message);
  }
}

void setColor(String color) {
  // Loop through the list of colors to find the matching color
  for (int colorIndex = 0; colorIndex < 12; colorIndex++) {
    if (color == colorName[colorIndex]) {
      // Set the color of each NeoPixel on the strip
      for (int pixel = 0; pixel < NUM_LEDS; pixel++) {
        leds[pixel] = CRGB(colorRGB[colorIndex][0], colorRGB[colorIndex][1], colorRGB[colorIndex][2]);
      }
      FastLED.show();
    }
  }
}

Control global @CheerLights devices

1. Join the Discord Server and utilize the CheerLights bot to set the color. Simply type /cheerlights in any of the channels on the CheerLights Discord Server to activate the bot.

   

2. Follow the instructions provided by the bot to set the color. This will allow you to control CheerLights devices globally.

   

How it works?

Here are the main parts of the code and explanations of their functions:

1. Include the required libraries:

   • WiFiS3.h: Used for handling Wi-Fi connections.

   • ArduinoMqttClient.h: Used for handling MQTT connections.

   • FastLED.h: Used for controlling NeoPixel LED strips.

2. Define some constants:

   • NUM_LEDS: The number of LEDs on the LED strip.

   • DATA_PIN: The data pin connected to Arduino for controlling the LED strip.

   • arduino_secrets.h: Header file containing Wi-Fi network name and password to protect sensitive information.

   • broker: Address of the MQTT server.

   • port: Port of the MQTT server.

   • topic: The MQTT topic to subscribe to.

3. Define some global variables:

   • CRGB leds[NUM_LEDS]: An array to store LED color data.

   • colorName: An array of color names supported by the CheerLights project.

   • colorRGB: An array of RGB color codes corresponding to color names.

4. setup() function:

   • Initialize serial communication.

   • Check if the Wi-Fi module is present and output its firmware version.

   • Attempt to connect to the Wi-Fi network; if it fails, wait 10 seconds and retry.

   • Upon successful connection, connect to the MQTT broker (server) and subscribe to the specified topic.

   • Initialize the NeoPixel LED strip.

5. loop() function:

   • Periodically call the mqttClient.poll() function to receive MQTT messages and send MQTT keep-alive signals.

   • Add a 5-second delay to avoid continuous connection.

6. printWifiData() and printCurrentNet() functions are used to output Wi-Fi network and connection information.

7. printMacAddress() function is used to print the MAC address in hexadecimal format.

8. onMqttMessage() function is a callback function triggered when an MQTT message is received. It outputs the received topic and message content, converting the message content to lowercase. If the topic is “cheerlights,” it calls the setColor() function to set the LED strip color.

9. setColor() function takes a color name as a parameter, then looks for a matching color in the colorName array. If a matching color is found, it sets the LED strip’s color to the corresponding RGB value and updates the LED strip’s color using the FastLED.show() function.