Note

Hello, welcome to the SunFounder Raspberry Pi & Arduino & ESP32 Enthusiasts Community on Facebook! Dive deeper into Raspberry Pi, Arduino, and ESP32 with fellow enthusiasts.

Why Join?

• Expert Support: Solve post-sale issues and technical challenges with help from our community and team.

• Learn & Share: Exchange tips and tutorials to enhance your skills.

• Exclusive Previews: Get early access to new product announcements and sneak peeks.

• Special Discounts: Enjoy exclusive discounts on our newest products.

• Festive Promotions and Giveaways: Take part in giveaways and holiday promotions.

👉 Ready to explore and create with us? Click [here] and join today!

Cloud Calling System with MQTT

Message Queuing Telemetry Transport (MQTT) is a straightforward messaging protocol. It is also the most widely used messaging protocol in the realm of the Internet of Things (IoT).

MQTT protocols define how IoT devices exchange data. They operate in an event-driven manner and are interconnected using the Publish/Subscribe model. The sender (Publisher) and the receiver (Subscriber) communicate through Topics. A device publishes a message on a specific topic, and all devices subscribed to that topic receive the message.

In this section, we’ll create a service bell system using UNO R4, HiveMQ (a free public MQTT broker service), and four buttons. Each of the four buttons corresponds to a restaurant table, and when a customer presses a button, you’ll be able to see which table needs service on HiveMQ.

Required Components

In this project, we need the following components.

It’s definitely convenient to buy a whole kit, here’s the link:

Name	ITEMS IN THIS KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

You can also buy them separately from the links below.

COMPONENT INTRODUCTION	PURCHASE LINK
Arduino Uno R4 WiFi	-
Breadboard	BUY
Jumper Wires	BUY
Button	BUY

Wiring

Schematic

How to play?

HiveMQ is an MQTT broker and client-based messaging platform that facilitates fast, efficient, and reliable data transfer to IoT devices.

1. Open HiveMQ Web Client in your web browser.

2. Connect the client to the default public proxy.

   

3. Click on Add New Topic Subscription.

   

4. Enter the topics you wish to follow and click Subscribe. Make sure the topics you set here are unique to avoid receiving messages from other users, and pay attention to case sensitivity.

   In this example code, we set the topic as SunFounder MQTT Test. If you have made any changes, ensure that the topic in the code matches the subscribed topic on the webpage.

   

Install the Library

To install the library, use the Arduino Library Manager and search for “ArduinoMqttClient” and install it.

ArduinoMqttClient.h: Used for MQTT communication.

Run the Code

Note

• You can open the file 04_mqtt_button.ino under the path of elite-explorer-kit-main\iot_project\04_mqtt_button directly.

• Or copy this code into Arduino IDE.

Note

In the code, SSID and password are stored in arduino_secrets.h. Before uploading this example, you need to modify them with your own WiFi credentials.

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)

04_mqtt_button.ino

/*
  The code is designed for an Arduino Uno R4 WiFi to establish a connection with 
  both a Wi-Fi network and an MQTT broker. It constantly monitors the status of 
  four buttons that are connected to digital inputs. Whenever a button is pressed, 
  it sends a message to a specific MQTT topic. Additionally, the code incorporates 
  functions for displaying Wi-Fi network information and managing received MQTT 
  messages.

  Board: Arduino Uno R4 WiFi
  Component: Button
  Library: https://github.com/arduino-libraries/ArduinoMqttClient (ArduinoMqttClient by Arduino)
*/

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;    // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;  // the WiFi radio's status

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "broker.hivemq.com";
int port = 1883;
const char topic[] = "SunFounder MQTT Test";

//init buttons & states
const int buttonPins[4] = { 2, 3, 4, 5 };
bool previousButtonStates[4] = { false, false, false, false };

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);

  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 5 seconds for connection:
    delay(5000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

  // You can provide a unique client ID, if not set the library uses Arduino-millis()
  // Each client must have a unique client ID
  // mqttClient.setId("clientId");

  // You can provide a username and password for authentication
  // mqttClient.setUsernamePassword("username", "password");

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1)
      ;
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  // set the message receive callback
  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(topic);
  Serial.println();

  // subscribe to a topic
  mqttClient.subscribe(topic);

  // topics can be unsubscribed using:
  // mqttClient.unsubscribe(topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(topic);
  Serial.println();

  // set button pins as INPUT_PULLUP
  for (int i = 0; i < 4; i++) {
    pinMode(buttonPins[i], INPUT_PULLUP);
    previousButtonStates[i] = digitalRead(buttonPins[i]);
  }
}

void loop() {

  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // Check button status
  for (int i = 0; i < 4; i++) {
    bool currentButtonState = digitalRead(buttonPins[i]);

    // If the button is pressed and its previous state was not pressed.
    if (!currentButtonState && previousButtonStates[i]) {
      sendButtonMessage(i + 1);  // The message that the send button has been pressed.
    }

    previousButtonStates[i] = currentButtonState;  // Update button status
  }

  // Add a delay to avoid constant pinging
  delay(50);
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");

  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}


void onMqttMessage(int messageSize) {
  // we received a message, print out the topic and contents
  Serial.print("Received a message with topic '");
  Serial.print(mqttClient.messageTopic());
  Serial.println("'");
  Serial.print("Message length: ");
  Serial.print(messageSize);
  Serial.println(" bytes:");

  // Read the message contents into a String
  String message = mqttClient.readString();

  // Convert the received message and comparison strings to lowercase
  message.toLowerCase();

  Serial.print("Message to me: ");
  Serial.println(message);

  Serial.println();
}

void sendButtonMessage(int buttonNumber) {
  String message = "Button " + String(buttonNumber) + " was pressed.";

  Serial.println(message);

  mqttClient.beginMessage(topic);
  mqttClient.print(message);
  mqttClient.endMessage();
}

After running the code, go back to HiveMQ Web Client, and when you press one of the buttons on the breadboard, you will see the Messages prompt on HiveMQ.

How it works?

This code is for an Arduino-based project that connects to Wi-Fi and communicates with an MQTT broker using the MQTT protocol. Additionally, it can detect whether four buttons are pressed and send the corresponding messages to the MQTT broker.

Here is a detailed explanation of the code:

1. Include Relevant Libraries:

   #include <WiFiS3.h>
   #include <ArduinoMqttClient.h>
   

2. Include Sensitive Information:

   • The arduino_secrets.h file contains the SSID and password for the Wi-Fi network.

   #include "arduino_secrets.h"
   char ssid[] = SECRET_SSID;
   char pass[] = SECRET_PASS;
   

3. Initialize Variables:

   • Variables for managing Wi-Fi and MQTT connections.

   • Initialize button pins and button states.

4. setup():

   • Initialize serial communication.

   • Check for the presence of the Wi-Fi module and attempt to connect to Wi-Fi.

   • Print network data.

   • Attempt to connect to the MQTT broker.

   • Subscribe to MQTT topics.

   • Set buttons to input mode.

5. loop():

   • Keep the MQTT connection active.

   • Check if each button is pressed, and if so, send MQTT messages.

6. Other Utility Functions:

   • printWifiData(): Prints information about the currently connected Wi-Fi network.

   • printCurrentNet(): Prints relevant data about the current network.

   • printMacAddress(byte mac[]): Prints the MAC address.

   • onMqttMessage(int messageSize): Callback function triggered when a message is received from the MQTT broker. It prints the received message topic and content.

   • sendButtonMessage(int buttonNumber): Use this function to send MQTT messages when a button is pressed.