Nota

Ciao, benvenuto nella community degli appassionati di SunFounder Raspberry Pi & Arduino & ESP32 su Facebook! Approfondisci Raspberry Pi, Arduino e ESP32 con altri appassionati.

Perché unirti?

• Supporto Esperto: Risolvi problemi post-vendita e sfide tecniche con l’aiuto della nostra community e del team.

• Apprendimento e Condivisione: Scambia suggerimenti e tutorial per migliorare le tue competenze.

• Anteprime Esclusive: Ottieni accesso anticipato a nuovi annunci di prodotti e anteprime.

• Sconti Speciali: Approfitta di sconti esclusivi sui nostri ultimi prodotti.

• Promozioni Festive e Concorsi: Partecipa a concorsi e promozioni speciali.

👉 Pronto per esplorare e creare con noi? Clicca [Qui] e unisciti oggi!

Sistema di Chiamata Cloud con MQTT

Il protocollo di messaggistica Message Queuing Telemetry Transport (MQTT) è semplice ma ampiamente utilizzato nel campo dell’Internet delle cose (IoT).

I protocolli MQTT definiscono come i dispositivi IoT scambiano dati. Operano in modo event-driven e sono interconnessi utilizzando il modello Publish/Subscribe. Il mittente (Publisher) e il ricevente (Subscriber) comunicano tramite Topics. Un dispositivo pubblica un messaggio su un topic specifico e tutti i dispositivi abbonati a quel topic ricevono il messaggio.

In questa sezione, creeremo un sistema di campanello di servizio utilizzando UNO R4, HiveMQ (un servizio broker MQTT pubblico gratuito) e quattro pulsanti. Ogni pulsante corrisponde a un tavolo del ristorante e quando un cliente preme un pulsante, sarà possibile vedere quale tavolo ha bisogno di assistenza su HiveMQ.

Componenti Necessari

Per questo progetto, sono necessari i seguenti componenti.

È sicuramente conveniente acquistare un kit completo, ecco il link:

Nome	ARTICOLI IN QUESTO KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

È anche possibile acquistarli separatamente dai link sottostanti.

INTRODUZIONE AI COMPONENTI	LINK DI ACQUISTO
Arduino Uno R4 WiFi	-
Breadboard	ACQUISTA
Cavi Jumper	ACQUISTA
Pulsante	ACQUISTA

Cablaggio

Schema

Come Funziona?

HiveMQ è una piattaforma di messaggistica basata su broker MQTT che facilita il trasferimento rapido, efficiente e affidabile dei dati ai dispositivi IoT.

1. Apri HiveMQ Web Client nel tuo browser web.

2. Collega il client al proxy pubblico predefinito.

   

3. Clicca su Aggiungi Nuova Sottoscrizione Topic.

   

4. Inserisci i topic che desideri seguire e clicca su Sottoscrivi. Assicurati che i topic che imposti qui siano unici per evitare di ricevere messaggi da altri utenti e presta attenzione alla sensibilità delle maiuscole e minuscole.

   In questo esempio di codice, impostiamo il topic come SunFounder MQTT Test. Se hai apportato modifiche, assicurati che il topic nel codice corrisponda al topic sottoscritto sulla pagina web.

   

Installazione della Libreria

Per installare la libreria, utilizza il Gestore delle Librerie Arduino e cerca «ArduinoMqttClient» e installalo.

ArduinoMqttClient.h: Utilizzato per la comunicazione MQTT.

Esecuzione del Codice

Nota

• Puoi aprire il file 04_mqtt_button.ino nel percorso elite-explorer-kit-main\iot_project\04_mqtt_button direttamente.

• Oppure copia questo codice nell’IDE di Arduino.

Nota

Nel codice, SSID e password sono memorizzati in arduino_secrets.h. Prima di caricare questo esempio, è necessario modificarli con le proprie credenziali WiFi. Inoltre, per motivi di sicurezza, assicurati che queste informazioni siano mantenute riservate durante la condivisione o la memorizzazione del codice.

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)

04_mqtt_button.ino

/*
  The code is designed for an Arduino Uno R4 WiFi to establish a connection with 
  both a Wi-Fi network and an MQTT broker. It constantly monitors the status of 
  four buttons that are connected to digital inputs. Whenever a button is pressed, 
  it sends a message to a specific MQTT topic. Additionally, the code incorporates 
  functions for displaying Wi-Fi network information and managing received MQTT 
  messages.

  Board: Arduino Uno R4 WiFi
  Component: Button
  Library: https://github.com/arduino-libraries/ArduinoMqttClient (ArduinoMqttClient by Arduino)
*/

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;    // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;  // the WiFi radio's status

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "broker.hivemq.com";
int port = 1883;
const char topic[] = "SunFounder MQTT Test";

//init buttons & states
const int buttonPins[4] = { 2, 3, 4, 5 };
bool previousButtonStates[4] = { false, false, false, false };

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);

  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 5 seconds for connection:
    delay(5000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

  // You can provide a unique client ID, if not set the library uses Arduino-millis()
  // Each client must have a unique client ID
  // mqttClient.setId("clientId");

  // You can provide a username and password for authentication
  // mqttClient.setUsernamePassword("username", "password");

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1)
      ;
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  // set the message receive callback
  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(topic);
  Serial.println();

  // subscribe to a topic
  mqttClient.subscribe(topic);

  // topics can be unsubscribed using:
  // mqttClient.unsubscribe(topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(topic);
  Serial.println();

  // set button pins as INPUT_PULLUP
  for (int i = 0; i < 4; i++) {
    pinMode(buttonPins[i], INPUT_PULLUP);
    previousButtonStates[i] = digitalRead(buttonPins[i]);
  }
}

void loop() {

  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // Check button status
  for (int i = 0; i < 4; i++) {
    bool currentButtonState = digitalRead(buttonPins[i]);

    // If the button is pressed and its previous state was not pressed.
    if (!currentButtonState && previousButtonStates[i]) {
      sendButtonMessage(i + 1);  // The message that the send button has been pressed.
    }

    previousButtonStates[i] = currentButtonState;  // Update button status
  }

  // Add a delay to avoid constant pinging
  delay(50);
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");

  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}


void onMqttMessage(int messageSize) {
  // we received a message, print out the topic and contents
  Serial.print("Received a message with topic '");
  Serial.print(mqttClient.messageTopic());
  Serial.println("'");
  Serial.print("Message length: ");
  Serial.print(messageSize);
  Serial.println(" bytes:");

  // Read the message contents into a String
  String message = mqttClient.readString();

  // Convert the received message and comparison strings to lowercase
  message.toLowerCase();

  Serial.print("Message to me: ");
  Serial.println(message);

  Serial.println();
}

void sendButtonMessage(int buttonNumber) {
  String message = "Button " + String(buttonNumber) + " was pressed.";

  Serial.println(message);

  mqttClient.beginMessage(topic);
  mqttClient.print(message);
  mqttClient.endMessage();
}

Dopo aver eseguito il codice, torna su HiveMQ Web Client e quando premi uno dei pulsanti sulla breadboard, vedrai il prompt Messaggi su HiveMQ.

Funzionamento del Codice

Questo codice è per un progetto basato su Arduino che si connette al WiFi e comunica con un broker MQTT utilizzando il protocollo MQTT. Inoltre, può rilevare se quattro pulsanti sono premuti e inviare i messaggi corrispondenti al broker MQTT.

Ecco una spiegazione dettagliata del codice:

1. Includi Librerie Pertinenti:

   #include <WiFiS3.h>
   #include <ArduinoMqttClient.h>
   

2. Includi Informazioni Sensibili:

   • Il file arduino_secrets.h contiene l’SSID e la password per la rete WiFi.

   #include "arduino_secrets.h"
   char ssid[] = SECRET_SSID;
   char pass[] = SECRET_PASS;
   

3. Inizializza Variabili:

   • Variabili per gestire le connessioni WiFi e MQTT.

   • Inizializza pin dei pulsanti e stati dei pulsanti.

4. setup():

   • Inizializza la comunicazione seriale.

   • Verifica la presenza del modulo WiFi e tenta di connettersi al WiFi.

   • Stampa dati di rete.

   • Tentativo di connessione al broker MQTT.

   • Sottoscrivi i topic MQTT.

   • Imposta i pulsanti in modalità input.

5. loop():

   • Mantieni attiva la connessione MQTT.

   • Verifica se ogni pulsante è premuto e, in caso affermativo, invia messaggi MQTT.

6. Altre Funzioni di Utilità:

   • printWifiData(): Stampa informazioni sulla rete WiFi attualmente connessa.

   • printCurrentNet(): Stampa dati rilevanti sulla rete attuale.

   • printMacAddress(byte mac[]): Stampa l’indirizzo MAC.

   • onMqttMessage(int messageSize): Funzione di callback attivata quando viene ricevuto un messaggio dal broker MQTT. Stampa il topic del messaggio ricevuto e il contenuto.

   • sendButtonMessage(int buttonNumber): Usa questa funzione per inviare messaggi MQTT quando viene premuto un pulsante.