Nota

Ciao, benvenuto nella community di appassionati SunFounder Raspberry Pi & Arduino & ESP32 su Facebook! Approfondisci Raspberry Pi, Arduino ed ESP32 insieme ad altri appassionati.

Perché unirti?

• Supporto Esperto: Risolvi problemi post-vendita e sfide tecniche con l’aiuto della nostra community e del team.

• Impara e Condividi: Scambia suggerimenti e tutorial per migliorare le tue competenze.

• Anteprime Esclusive: Ottieni accesso anticipato a nuovi annunci di prodotti e anteprime.

• Sconti Speciali: Approfitta di sconti esclusivi sui nostri prodotti più recenti.

• Promozioni Festive e Giveaway: Partecipa a giveaway e promozioni festive.

👉 Pronto per esplorare e creare con noi? Clicca [Qui] e unisciti oggi!

CheerLights

CheerLights è una rete globale di luci sincronizzate che può essere controllata da chiunque. Unisciti alla comunità @CheerLights - Twitter di LED che cambiano colore, permettendo ai LED di tutto il mondo di cambiare colore simultaneamente. Posiziona i tuoi LED in un angolo del tuo ufficio per ricordarti che non sei solo.

In questo progetto utilizziamo anche MQTT, ma invece di pubblicare i nostri messaggi, ci iscriviamo al topic «cheerlights». Questo ci permette di ricevere messaggi inviati da altri al topic «cheerlights» e di utilizzare tali informazioni per cambiare il colore della nostra striscia LED di conseguenza.

Componenti Necessari

In questo progetto, abbiamo bisogno dei seguenti componenti.

È sicuramente conveniente acquistare un kit completo, ecco il link:

Nome	ARTICOLI IN QUESTO KIT	LINK
Elite Explorer Kit	300+	Elite Explorer Kit

È anche possibile acquistarli separatamente dai link sottostanti.

INTRODUZIONE AI COMPONENTI	LINK PER L’ACQUISTO
Arduino Uno R4 WiFi	-
Cavi Jumper	ACQUISTA
Striscia LED RGB WS2812 8 LEDs	ACQUISTA

Cablaggio

Schema

Installa la Libreria

Per installare la libreria, utilizza il Gestore delle Librerie Arduino e cerca «ArduinoMqttClient» e «FastLED» e installale.

ArduinoMqttClient.h: Utilizzato per la comunicazione MQTT.

FastLED.h: Utilizzato per pilotare la striscia LED RGB.

Importante

Con il rilascio di FastLED 3.7.0, la libreria FastLED supporta ufficialmente Arduino UNO R4. Pertanto, non è più necessario installare manualmente la versione di sviluppo. Aggiorna o installa semplicemente la libreria FastLED utilizzando il Gestore delle Librerie Arduino.

Avvertimento

[Non aggiornato] Poiché la libreria FastLED non ha ancora rilasciato una versione che supporta ufficialmente Arduino R4, dovrai scaricare l'ultima versione di sviluppo della libreria FastLED e sovrascrivere i file esistenti della libreria FastLED. Per istruzioni dettagliate su come fare ciò, consulta la sezione Installazione Manuale. (Questa nota sarà ritirata quando la libreria FastLED rilascerà ufficialmente un aggiornamento che supporta Arduino UNO R4.)

Esegui il Codice

Nota

• Puoi aprire il file 05_cheerlight.ino nel percorso elite-explorer-kit-main\iot_project\05_cheerlight direttamente.

• Oppure copia questo codice nell’IDE di Arduino.

Nota

Nel codice, SSID e password sono memorizzati in arduino_secrets.h. Prima di caricare questo esempio, è necessario modificarli con le proprie credenziali WiFi. Inoltre, per motivi di sicurezza, assicurati che queste informazioni siano mantenute riservate durante la condivisione o la memorizzazione del codice.

arduino_secrets.h

#define SECRET_SSID "your_ssid"        // your network SSID (name)
#define SECRET_PASS "your_password"        // your network password (use for WPA, or use as key for WEP)

05_cheerlight.ino

/*
  The code is designed for an Arduino Uno R4 WiFi to connect to a Wi-Fi network, 
  subscribe to an MQTT topic, and control a chain of NeoPixel LEDs based on messages 
  received from the MQTT broker. It listens for color commands from the cheerlights 
  topic and updates the LED colors accordingly.

  Board: Arduino Uno R4 WiFi
  Component: WS2812
  Library: https://github.com/arduino-libraries/ArduinoMqttClient (ArduinoMqttClient by Arduino)
           https://github.com/FastLED/FastLED (FastLED by Daniel Garcia)
           
*/

#include <WiFiS3.h>
#include <ArduinoMqttClient.h>
#include <FastLED.h>

#define NUM_LEDS 8  // Number of LEDs in the chain
#define DATA_PIN 6  // Data pin for LED control

#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;    // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;  // the WiFi radio's status

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "mqtt.cheerlights.com";
int port = 1883;
const char topic[] = "cheerlights";



CRGB leds[NUM_LEDS];  // Array to hold LED color data

// Define the supported CheerLights colors and their RGB values
String colorName[] = { "red", "pink", "green", "blue", "cyan", "white", "warmwhite", "oldlace", "purple", "magenta", "yellow", "orange" };

int colorRGB[][3] = { 255, 0, 0,      // "red"
                      255, 192, 203,  // "pink"
                      0, 255, 0,      // "green"
                      0, 0, 255,      // "blue"
                      0, 255, 255,    // "cyan"
                      255, 255, 255,  // "white"
                      255, 223, 223,  // "warmwhite"
                      255, 223, 223,  // "oldlace"
                      128, 0, 128,    // "purple"
                      255, 0, 255,    // "magenta"
                      255, 255, 0,    // "yellow"
                      255, 165, 0 };  // "orange"


void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);

  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true)
      ;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

  // You can provide a unique client ID, if not set the library uses Arduino-millis()
  // Each client must have a unique client ID
  // mqttClient.setId("clientId");

  // You can provide a username and password for authentication
  // mqttClient.setUsernamePassword("username", "password");

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1)
      ;
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  // set the message receive callback
  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(topic);
  Serial.println();

  // subscribe to a topic
  mqttClient.subscribe(topic);

  // topics can be unsubscribed using:
  // mqttClient.unsubscribe(topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(topic);
  Serial.println();

  FastLED.addLeds<NEOPIXEL, DATA_PIN>(leds, NUM_LEDS);  // Initialize LEDs
}

void loop() {

  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // Add a delay to avoid constant pinging
  delay(5000);
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");

  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}


void onMqttMessage(int messageSize) {
  // we received a message, print out the topic and contents
  Serial.print("Received a message with topic '");
  Serial.print(mqttClient.messageTopic());
  Serial.println("'");
  Serial.print("Message length: ");
  Serial.print(messageSize);
  Serial.println(" bytes:");

  // Read the message contents into a String
  String message = mqttClient.readString();

  // Convert the received message and comparison strings to lowercase
  message.toLowerCase();

  // If a message is received on the topic, you will check this message.
  // Changes the output state according to the message
  if (String(topic) == "cheerlights") {
    Serial.print("Changing color to ");
    Serial.println(message);
    setColor(message);
  }
}

void setColor(String color) {
  // Loop through the list of colors to find the matching color
  for (int colorIndex = 0; colorIndex < 12; colorIndex++) {
    if (color == colorName[colorIndex]) {
      // Set the color of each NeoPixel on the strip
      for (int pixel = 0; pixel < NUM_LEDS; pixel++) {
        leds[pixel] = CRGB(colorRGB[colorIndex][0], colorRGB[colorIndex][1], colorRGB[colorIndex][2]);
      }
      FastLED.show();
    }
  }
}

Controlla i dispositivi globali @CheerLights

1. Unisciti al Server Discord e utilizza il bot CheerLights per impostare il colore. Digita semplicemente /cheerlights in uno dei canali sul CheerLights Discord Server per attivare il bot.

   

2. Segui le istruzioni fornite dal bot per impostare il colore. Questo ti permetterà di controllare i dispositivi CheerLights globalmente.

   

Come Funziona?

Ecco le principali parti del codice e le spiegazioni delle loro funzioni:

1. Includi le librerie necessarie:

   • WiFiS3.h: Utilizzata per gestire le connessioni Wi-Fi.

   • ArduinoMqttClient.h: Utilizzata per gestire le connessioni MQTT.

   • FastLED.h: Utilizzata per controllare le strisce LED NeoPixel.

2. Definisci alcune costanti:

   • NUM_LEDS: Il numero di LED sulla striscia LED.

   • DATA_PIN: Il pin dati collegato ad Arduino per controllare la striscia LED.

   • arduino_secrets.h: File header contenente il nome e la password della rete Wi-Fi per proteggere le informazioni sensibili.

   • broker: Indirizzo del server MQTT.

   • port: Porta del server MQTT.

   • topic: Il topic MQTT a cui iscriversi.

3. Definisci alcune variabili globali:

   • CRGB leds[NUM_LEDS]: Un array per memorizzare i dati del colore dei LED.

   • colorName: Un array di nomi di colori supportati dal progetto CheerLights.

   • colorRGB: Un array di codici colore RGB corrispondenti ai nomi dei colori.

4. Funzione setup():

   • Inizializza la comunicazione seriale.

   • Verifica se il modulo Wi-Fi è presente e stampa la versione del firmware.

   • Tenta di connettersi alla rete Wi-Fi; se fallisce, attende 10 secondi e riprova.

   • Una volta connesso con successo, si connette al broker MQTT (server) e si iscrive al topic specificato.

   • Inizializza la striscia LED NeoPixel.

5. Funzione loop():

   • Chiama periodicamente la funzione mqttClient.poll() per ricevere messaggi MQTT e inviare segnali di keep-alive MQTT.

   • Aggiungi un ritardo di 5 secondi per evitare una connessione continua.

6. Le funzioni printWifiData() e printCurrentNet() sono utilizzate per stampare le informazioni sulla rete Wi-Fi e sulla connessione.

7. La funzione printMacAddress() è utilizzata per stampare l’indirizzo MAC in formato esadecimale.

8. La funzione onMqttMessage() è una funzione di callback attivata quando viene ricevuto un messaggio MQTT. Stampa il topic del messaggio ricevuto e il contenuto, convertendo il contenuto del messaggio in minuscolo. Se il topic è «cheerlights», chiama la funzione setColor() per impostare il colore della striscia LED.

9. La funzione setColor() prende un nome di colore come parametro, quindi cerca un colore corrispondente nell’array colorName. Se viene trovato un colore corrispondente, imposta il colore della striscia LED sul valore RGB corrispondente e aggiorna``` la striscia LED utilizzando la funzione FastLED.show().