注釈

こんにちは、SunFounderのRaspberry Pi & Arduino & ESP32愛好家コミュニティへようこそ！Facebook上でRaspberry Pi、Arduino、ESP32についてもっと深く掘り下げ、他の愛好家と交流しましょう。

参加する理由は？

エキスパートサポート：コミュニティやチームの助けを借りて、販売後の問題や技術的な課題を解決します。
学び＆共有：ヒントやチュートリアルを交換してスキルを向上させましょう。
独占的なプレビュー：新製品の発表や先行プレビューに早期アクセスしましょう。
特別割引：最新製品の独占割引をお楽しみください。
祭りのプロモーションとギフト：ギフトや祝日のプロモーションに参加しましょう。

👉 私たちと一緒に探索し、創造する準備はできていますか？[ ここ]をクリックして今すぐ参加しましょう！

Wi-Fiに接続する

このチュートリアルでは、ArduinoボードをWi-Fiネットワークに接続するための基本的なステップを案内します。Wi-Fiモジュールの初期化、ファームウェアの確認、SSIDとパスワードを使用した安全なネットワークへの参加方法を学びます。接続後、シリアルコンソールからデバイスのIPやMACアドレス、ネットワークの信号強度などの重要なネットワーク情報をモニタリングする方法を発見します。このチュートリアルは、Wi-Fi接続の実用的なガイドであり、Arduinoを使用したネットワークモニタリングの導入としても役立ちます。これにより、信頼性のあるWi-Fi接続を確立し維持することができます。

1. コードをアップロードする

elite-explorer-kit-main\r4_new_feature\01-wifi_connect のパスの下にある 01-wifi_connect.ino ファイルを開くか、このコードを Arduino IDE にコピーします。

注釈

Wi-Fi®サポートは、Arduino UNO R4 Coreに付属する内蔵の WiFiS3 ライブラリを介して有効にされます。コアのインストール時に自動的に WiFiS3 ライブラリもインストールされます。

arduino_secrets.h を作成または変更し、 SECRET_SSID と SECRET_PASS を接続したいWi-Fiの名前とパスワードに置き換える必要があります。ファイルには以下が含まれている必要があります:

//arduino_secrets.h header file
#define SECRET_SSID "yournetwork"
#define SECRET_PASS "yourpassword"

arduino_secrets.h

//arduino_secrets.h header file
#define SECRET_SSID "your_ssid"
#define SECRET_PASS "your_password"

01-wifi_connect.ino

/*
  This code is designed to establish a WiFi connection using a WiFi module 
  on an Arduino Uno R4 board. It initializes serial communication, verifies 
  the presence and firmware version of the WiFi module, attempts to connect 
  to a specified WiFi network, and once connected, prints network information 
  to the serial monitor. It continuously checks the network connection every 
  10 seconds in the loop.

  Board: Arduino Uno R4 
*/


#include <WiFiS3.h>

#include "arduino_secrets.h" 
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID;        // your network SSID (name)
char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;     // the WiFi radio's status

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true);
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }

  // you're connected now, so print out the data:
  Serial.print("You're connected to the network");
  printCurrentNet();
  printWifiData();

}

void loop() {
  // check the network connection once every 10 seconds:
  delay(10000);
  printCurrentNet();
}

void printWifiData() {
  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  
  Serial.println(ip);

  // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  printMacAddress(mac);
}

void printCurrentNet() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);
  Serial.print("BSSID: ");
  printMacAddress(bssid);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption, HEX);
  Serial.println();
}

void printMacAddress(byte mac[]) {
  for (int i = 5; i >= 0; i--) {
    if (mac[i] < 16) {
      Serial.print("0");
    }
    Serial.print(mac[i], HEX);
    if (i > 0) {
      Serial.print(":");
    }
  }
  Serial.println();
}

シリアルモニタを開くと、以下のような内容が表示されます。ArduinoはデバイスのIPとMACアドレス、ネットワークの信号強度を出力します。

2. コードの説明

ライブラリと秘密データを含める
```
#include <WiFiS3.h>
#include "arduino_secrets.h"
```
- WiFiS3 はWi-Fi接続のための関数を提供するライブラリです。R4コアをインストールすると自動的にWiFiS3ライブラリがインストールされます。
- arduino_secrets.h はメインコードにSSIDやパスワードが露出しないようにするための別のファイルです。ネットワークとパスワードを別々に保管することで、Wi-Fi資格情報の偶発的な共有を減らします。
グローバル変数の宣言
```
char ssid[] = SECRET_SSID;
char pass[] = SECRET_PASS;
int status = WL_IDLE_STATUS;
```
- ssid と pass にはネットワーク名とパスワードが含まれます。
- status はWi-Fi接続の現在のステータスを格納します。
setup() 関数

シリアルインターフェースは9600のボーレートで初期化されます。 while (!Serial); 行は、シリアル接続が確立されるまでプログラムが待機することを保証します。
```
void setup() {
     //Initialize serial and wait for port to open:
    Serial.begin(9600);
    while (!Serial) {
      ; // wait for serial port to connect. Needed for native USB port only
    }
    ...
}
```
そして、コードはWi-Fiモジュールが利用可能かどうかをチェックします。利用不可の場合、プログラムは停止し、それ以上の実行を防ぎます。
```
...
// check for the WiFi module:
if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true);
}
...
```
このコードの部分では、uno R4 wifiのファームウェアバージョンが最新かどうかを確認します。最新バージョンでない場合、アップグレードの促し表示がされます。ファームウェアのアップグレードについては、 UNO R4 WiFiボードのラジオモジュールファームウェアの更新を参照してください。
```
...
String fv = WiFi.firmwareVersion();
if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
}
...
```
loop() 関数
```
void loop() {
  // check the network connection once every 10 seconds:
  delay(10000);
  printCurrentNet();
}
```
- 10秒ごとに printCurrentNet() 関数が呼び出され、現在のネットワークの詳細を印刷します。

参照

UNO R4 WiFi Network 例